Excelウィンドウを常に最前面に保つにはどうすればよいですか？

マルチタスク中にExcelウィンドウが他のアプリケーションの背後に隠れてしまうことに悩んだことはありませんか？多くのユーザーは、他のプログラムを使用しながらExcelを参照したりデータを入力したりできるよう、Excelワークブックウィンドウを前面に表示しておきたいと考えています。例えば、ブラウザや別のデスクトップアプリから手動で数字を転記する場合などです。この機能は、デュアルモニターを使用している方、プレゼンテーションを行う方、または頻繁にExcelと他のソフトウェアを行き来するユーザーにとって特に便利です。

残念ながら、Microsoft Excelにはウィンドウを常に最前面に表示するための組み込み設定やオプションは用意されていません。使用しているOfficeのバージョンや32ビット版・64ビット版に関係なく、標準インターフェースではExcelをすべての開いているウィンドウの上に固定することはできません。しかし、この機能を実現する代替ソリューションがあります。以下では、さまざまな使用シナリオに対応したVBAコードによる方法を紹介します。

VBAコードを使用してExcelウィンドウを常に最前面に保つ

VBAコードを使用してExcelウィンドウを常に最前面に保つ

このVBAコードソリューションでは、アクティブなExcelウィンドウを他のすべてのウィンドウの上に固定し、他のアプリケーションウィンドウによって隠されないようにすることができます。Officeの32ビット版と64ビット版のどちらでも動作します。このアプローチは、高度なExcelユーザー、または追加ソフトウェアのインストールが許可されていない環境での利用に特に適しています。

作業を進める前に、マクロを実行すると予期しないエラーやExcelの再起動が発生することがあるため、作業内容を保存してください。また、このソリューションはマクロを実行したExcelウィンドウのみに影響することに注意してください。他のインスタンスは自動的には最前面に表示されません。

1. キーボードで ALT + F11 キーを押して、Microsoft Visual Basic for Applicationsエディタウィンドウを起動します。この環境では、Excelワークブック用のVBAコードを入力および管理できます。

2. VBAエディタで、挿入 > モジュール をクリックして新しいモジュールをワークブックに追加します。次に、以下のVBAコードをコピーして開いたモジュールウィンドウに貼り付けます:

VBAコード: Excelウィンドウを常に最前面に保つ

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

このコードはシステムレベルのAPI呼び出しを使用してウィンドウの固定状態を制御します。VBAコードが正しく機能するために、Excelの設定でマクロが有効になっていることを確認してください。「マクロが無効」のメッセージが表示された場合は、Excelの信頼センターの設定を更新してマクロの実行を許可する必要があります。

3. コードを入力したら、F5キーを押すかVBAエディタの実行ボタンをクリックします。マクロダイアログボックスが表示され、利用可能なマクロがリストされます。SetXLOnTopという名前のマクロを選択し、実行をクリックして実行します。これにより、現在のExcelウィンドウに「常に最前面」の状態が適用されます。次の図をご覧ください:

4. マクロの実行が完了すると、Excelウィンドウは開かれているすべてのアプリケーションの上に表示されるようになり、Excelウィンドウが隠れることなく複数のプログラム間での参照やデータ入力が容易になります。

この設定は、手動で元に戻すまで継続します。ウィンドウを最小化して復元しても、「常に最前面」の状態は通常保持されますが、Excelを閉じて再度開く場合は、再度マクロを実行する必要があります。

注意: Excelウィンドウを通常の状態に戻したい場合（常に最前面にならない状態）、もう一度操作を繰り返します。F5キーを押してマクロダイアログを開き、SetXNormalマクロを選択して実行をクリックします。これで、Excelウィンドウは通常どおり動作します。

トラブルシューティングのヒント: マクロを実行中にエラーが発生した場合は、マクロのセキュリティ設定を再確認し、すべてのマクロコードが正しく貼り付けられていることを確認してください。一部の企業環境では、特定のウィンドウ管理操作が制限されている場合があるため、期待通りに動作しない場合はIT部門に相談してください。また、Excelを管理者として実行する必要はありません。通常のユーザー権限で実行してください。

このVBAソリューションは、サードパーティのソフトウェアをインストールせず、Excelの組み込みスクリプト機能を使用できることを望む場合に理想的です。ただし、複数のアプリケーションウィンドウを固定する必要がある場合は、ウィンドウ位置を管理する専用ツールを利用した方が良いでしょう。