Excelで全てのフォルダとサブフォルダをリストするにはどうすればよいですか？

特定のディレクトリからワークシートにすべてのフォルダとサブフォルダをリストするという問題に悩まされたことはありますか？ Excelでは、特定のディレクトリ内のすべてのフォルダ名を一度に取得するための迅速で便利な方法はありません。このタスクに対処するために、この記事がお役に立つかもしれません。

VBAコードを使用してすべてのフォルダとサブフォルダをリストする

VBAコードを使用してすべてのフォルダとサブフォルダをリストする

指定されたディレクトリからすべてのフォルダ名を取得したい場合、次のVBAコードが役立つかもしれません。以下の手順で行ってください：

1. 「ALT + F11」キーを押したままにすると、「Microsoft Visual Basic for Applications ウィンドウ」が開きます。

2. 「挿入」>「モジュール」をクリックし、次のコードを「モジュールウィンドウ」に貼り付けます。

VBAコード: すべてのフォルダとサブフォルダ名をリストする

Sub FolderNames()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim xPath As String
Dim xWs As Worksheet
Dim fso As Object, j As Long, folder1 As Object
With Application.FileDialog(msoFileDialogFolderPicker)
    .Title = "Choose the folder"
    .Show
End With
On Error Resume Next
xPath = Application.FileDialog(msoFileDialogFolderPicker).SelectedItems(1) & "\"
Application.Workbooks.Add
Set xWs = Application.ActiveSheet
xWs.Cells(1, 1).Value = xPath
xWs.Cells(2, 1).Resize(1, 5).Value = Array("Path", "Dir", "Name", "Date Created", "Date Last Modified")
Set fso = CreateObject("Scripting.FileSystemObject")
Set folder1 = fso.getFolder(xPath)
getSubFolder folder1
xWs.Cells(2, 1).Resize(1, 5).Interior.Color = 65535
xWs.Cells(2, 1).Resize(1, 5).EntireColumn.AutoFit
Application.ScreenUpdating = True
End Sub
Sub getSubFolder(ByRef prntfld As Object)
Dim SubFolder As Object
Dim subfld As Object
Dim xRow As Long
For Each SubFolder In prntfld.SubFolders
    xRow = Range("A1").End(xlDown).Row + 1
    Cells(xRow, 1).Resize(1, 5).Value = Array(SubFolder.Path, Left(SubFolder.Path, InStrRev(SubFolder.Path, "\")), SubFolder.Name, SubFolder.DateCreated, SubFolder.DateLastModified)
Next SubFolder
For Each subfld In prntfld.SubFolders
    getSubFolder subfld
Next subfld
End Sub

3. 次に「F5」キーを押してこのコードを実行すると、「フォルダを選択」ウィンドウがポップアップ表示されます。その後、フォルダとサブフォルダ名をリストしたいディレクトリを選択します。スクリーンショットをご覧ください：

4. 「OK」をクリックすると、新しいワークブックにフォルダとサブフォルダのパス、ディレクトリ、名前、作成日時、最終変更日時が表示されます。スクリーンショットをご覧ください：

関連記事：

Excelでディレクトリ内のファイルをワークシートにリストするにはどうすればよいですか？