ワークブックからすべてのピボットテーブルをリストするにはどうすればよいですか？

多数のピボットテーブルを含む大規模なワークブックがあり、このワークブック内のすべてのピボットテーブルをリストしたいとします。それは可能でしょうか？もちろん可能です。この記事で紹介する次のVBAコードがお手伝いします。詳細は以下の記事をお読みください。

VBAコードを使用してワークブックからすべてのピボットテーブルをリストする

VBAコードを使用してワークブックからすべてのピボットテーブルをリストする

次のVBAコードは、すべてのピボットテーブル名とその属性（ソースデータ範囲、ワークシート名、更新日など）をリストするのに役立ちます。

1. すべてのピボットテーブルをリストしたいワークブックを開きます。

2. ALT + F11キーを押しながら押すと、Microsoft Visual Basic for Applicationsウィンドウが開きます。

3. 「挿入」>「モジュール」をクリックし、次のコードをモジュールウィンドウに貼り付けます。

VBAコード：ワークブックからすべてのピボットテーブルをリストする

Sub ListPivotsInfor()
'Update 20141112
    Dim St As Worksheet
    Dim NewSt As Worksheet
    Dim pt As PivotTable
    Dim I, K As Long
    Application.ScreenUpdating = False
    Set NewSt = Worksheets.Add
    I = 1: K = 2
    With NewSt
        .Cells(I, 1) = "Name"
        .Cells(I, 2) = "Source"
        .Cells(I, 3) = "Refreshed by"
        .Cells(I, 4) = "Refreshed"
        .Cells(I, 5) = "Sheet"
        .Cells(I, 6) = "Location"
        For Each St In ActiveWorkbook.Worksheets
            For Each pt In St.PivotTables
                I = I + 1
                .Cells(I, 1).Value = pt.Name
                .Cells(I, 2).Value = pt.SourceData
                .Cells(I, 3).Value = pt.RefreshName
                .Cells(I, 4).Value = pt.RefreshDate
                .Cells(I, 5).Value = St.Name
                .Cells(I, 6).Value = pt.TableRange1.Address
            Next
        Next
        .Activate
    End With
    Application.ScreenUpdating = True
End Sub

4. 次に、F5キーを押してこのコードを実行すると、すべてのピボットテーブル名、ソースデータ範囲、ワークシート名、その他の属性が新しいワークシートにリストされ、アクティブなワークシートの前に配置されます。次のスクリーンショットのように表示されます。

関連記事：

ワークブックにピボットテーブルが存在するかどうかを確認するにはどうすればよいですか？

複数のフィールドをピボットテーブルに追加するにはどうすればよいですか？