Excelでコメントインジケータの色を変更するにはどうすればよいですか？

Excelでは、コメントを挿入すると、セルの右上に小さな赤い三角形のインジケータが表示されます。多くのExcelユーザーは、この赤いインジケータの色を他の好きな色に変更できるかどうか疑問に思うかもしれません。この記事では、そのタスクを完了するための回避策について説明します。

VBAコードを使用してコメントインジケータの色を変更する

VBAコードを使用してコメントインジケータの色を変更する

コメントインジケータの色を迅速かつ簡単に変更する直接的な方法はありませんが、次のVBAコードを使用すると、アクティブなシート上の必要な特定の色で各コメントインジケータに重なる三角形の図形を描画できます。

1. コメントインジケータの色を変更したいワークシートをアクティブにします。

2. ALT + F11キーを押してMicrosoft Visual Basic for Applicationsウィンドウを開きます。

3. 「挿入」＞「モジュール」をクリックし、次のコードをモジュールウィンドウに貼り付けます。

VBAコード：アクティブなシートでコメントインジケータの色を変更する

Sub CoverCommentIndicator()
'Update 20141110
Dim pWs As Worksheet
Dim pComment As Comment
Dim pRng As Range
Dim pShape As Shape
Set pWs = Application.ActiveSheet
wShp = 6
hShp = 4
For Each pComment In pWs.Comments
  Set pRng = pComment.Parent
  Set pShape = pWs.Shapes.AddShape(msoShapeRightTriangle, pRng.Offset(0, 1).Left - wShp, pRng.Top, wShp, hShp)
  With pShape
    .Flip msoFlipVertical
    .Flip msoFlipHorizontal
    .Fill.ForeColor.SchemeColor = 12
    .Fill.Visible = msoTrue
    .Fill.Solid
    .Line.Visible = msoFalse
  End With
Next
End Sub

4. コードを貼り付けた後、F5キーを押してコードを実行すると、すべての赤い三角形のインジケータが青い三角形で覆われます（次のスクリーンショットを参照）。

注意：

1. 上記のコードでは、スクリプト内の色コード（.Fill.ForeColor.SchemeColor = 12）を変更することで、好きな色に青色を変更できます。

2. 上記のVBAで追加した三角形の図形は、セルのサイズを変更するとそのサイズも変わります。

3. すぐにすべての色付き三角形の図形を削除したい場合、次のVBAコードがあなたを助けるでしょう：

VBAコード：コメントインジケータの上にある三角形の図形を削除する

Sub RemoveIndicatorShapes()
'Update 20141110
Dim pWs As Worksheet
Dim pShape As Shape
Set pWs = Application.ActiveSheet
For Each pShape In pWs.Shapes
    If Not pShape.TopLeftCell.Comment Is Nothing Then
      If pShape.AutoShapeType = msoShapeRightTriangle Then
        pShape.Delete
      End If
    End If
Next
End Sub

関連記事：

Excelですべてのコメント付きセルをハイライトするにはどうすればよいですか？

Excelですべてのコメントとコメントインジケータを表示または非表示にするにはどうすればよいですか？