ExcelからOutlook経由でリスト内の複数の受信者にメールを送信するにはどうすればよいですか？

ワークシートの列に複数のメールアドレスがあり、Outlookを開かずにExcelからこの受信者リストに直接メールを送信したい場合があります。この記事では、Excelから同時に複数の受信者にメールを送信する方法について説明します。

VBAコードを使用してExcelから複数の受信者にメールを送信する

VBAコードを使用して現在のワークブックを添付ファイルとして複数の受信者にメールを送信する

VBAコードを使用してExcelから複数の受信者にメールを送信する

以下の手順で、VBAコードを使用して一度に複数の受信者にメッセージを送信できます：

1. ALT + F11キーを押しながら押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2. 「 挿入」>「モジュール」をクリックし、次のコードを モジュールウィンドウに貼り付けます。

VBAコード：複数の受信者にメールを送信

Sub sendmultiple()
'updateby Extendoffice
    Dim xOTApp As Object
    Dim xMItem As Object
    Dim xCell As Range
    Dim xRg As Range
    Dim xEmailAddr As String
    Dim xTxt As String
    On Error Resume Next
    xTxt = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Please select the addresses list:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Set xOTApp = CreateObject("Outlook.Application")
    For Each xCell In xRg
        If xCell.Value Like "*@*" Then
            If xEmailAddr = "" Then
                xEmailAddr = xCell.Value
            Else
                xEmailAddr = xEmailAddr & ";" & xCell.Value
            End If
        End If
    Next
    Set xMItem = xOTApp.CreateItem(0)
    With xMItem
        .To = xEmailAddr
        .Display
    End With
End Sub

3. そして、F5キーを押してこのコードを実行すると、アドレスリストを選択するように促すボックスが表示されます。スクリーンショットをご覧ください：

4. 「OK」をクリックすると、Outlookメッセージウィンドウが表示され、選択したすべてのメールアドレスが「宛先」フィールドに追加されていることが確認できます。その後、件名を入力し、メッセージを作成します。スクリーンショットをご覧ください：

5. メッセージの作成が完了したら、「送信」ボタンをクリックしてください。このメッセージは、ワークシートリストにあるこれらの受信者に送信されます。

VBAコードを使用して現在のワークブックを添付ファイルとして複数の受信者にメールを送信する

現在のワークブックを添付ファイルとして複数の受信者にメッセージを送信する必要がある場合は、次のVBAコードを適用できます。

1. ALT + F11キーを押しながら押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2. 「挿入」> 「モジュール」をクリックし、次のコードをモジュールウィンドウに貼り付けます。

VBAコード：現在のワークブックを添付ファイルとして複数の受信者にメールを送信

Sub EmailAttachmentRecipients()
'updateby Extendoffice
    Dim xOutlook As Object
    Dim xMailItem As Object
    Dim xRg As Range
    Dim xCell As Range
    Dim xEmailAddr As String
    Dim xTxt As String
    On Error Resume Next
    xTxt = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Please select the arresses list:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Set xOutlook = CreateObject("Outlook.Application")
    Set xMailItem = xOutlook.CreateItem(0)
    For Each xCell In xRg
        If xCell.Value Like "*@*" Then
            If xEmailAddr = "" Then
                xEmailAddr = xCell.Value
            Else
                xEmailAddr = xEmailAddr & ";" & xCell.Value
            End If
        End If
    Next
    With xMailItem
        .To = xEmailAddr
        .CC = ""
        .Subject = ""
        .Body = ""
        .Attachments.Add ActiveWorkbook.FullName
        .Display
    End With
    Set xOutlook = Nothing
    Set xMailItem = Nothing
End Sub

3. コードを貼り付けた後、F5キーを押してこのコードを実行すると、送信したいアドレスを選択するように促すボックスが表示されます。スクリーンショットをご覧ください：

4. 「 OK」ボタンをクリックすると、Outlook メッセージウィンドウが表示され、すべてのメールアドレスが「宛先」フィールドに追加され、現在のワークブックも添付ファイルとして挿入されています。その後、件名を入力し、メッセージを作成します。スクリーンショットをご覧ください：

5. 現在のワークブックを添付ファイルとして受信者リストにこのメッセージを送信するために、「送信」ボタンをクリックします。

関連記事：

ExcelからOutlook経由でリストに個別の大量メールを送信するにはどうすればよいですか？