Excelで可能なすべての順列を生成または一覧表示するにはどうすればよいですか？

たとえば、XYZというXNUMXつの文字がありますが、XYZ、XZY、YXZ、YZX、ZXY、ZYXのXNUMXつの異なる結果を得るために、これらXNUMXつの文字に基づいて可能なすべての順列を一覧表示したいと思います。 Excelで、さまざまな文字数に基づいてすべての順列をすばやく生成または一覧表示するにはどうすればよいでしょうか。

VBAコードの文字に基づいて、考えられるすべての順列を生成または一覧表示します

VBAコードの文字に基づいて、考えられるすべての順列を生成または一覧表示します

次のVBAコードは、特定の文字数に基づいてすべての順列を一覧表示するのに役立つ場合があります。次のようにしてください。

1。 を押し続けます Alt + F11 キーを押して アプリケーション向け Microsoft Visual Basic 窓。

2に設定します。 OK をクリックします。 インセット > モジュール、次のコードをに貼り付けます モジュール 窓。

VBAコード：Excelで可能なすべての順列を一覧表示します

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3。 次に、 F5 このコードを実行するためのキーを押すと、すべての順列を一覧表示する文字を入力するように促すプロンプトボックスが表示されます。スクリーンショットを参照してください。

4。 文字を入力した後、をクリックします OK ボタンをクリックすると、すべての可能な順列がアクティブなワークシートの列Aに表示されます。 スクリーンショットを参照してください：

Note：入力した文字長が8文字以上の場合、順列が多すぎるため、このコードは機能しません。