Excelで数式からセル参照を抽出するにはどうすればよいですか？

いくつかの長い数式があり、次のスクリーンショットに示すように、これらの数式からすべてのセル参照を抽出したいとします。できるだけ早く数式からセル参照を抽出するにはどうすればよいでしょうか？

ユーザー定義関数を使用して数式からセル参照を抽出

ユーザー定義関数を使用して数式からセル参照を抽出

数式からセル参照を抽出するために、以下のVBAコードが役立つかもしれません。以下のように操作してください：

1. ALT + F11キーを押したままにして、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2. 「 挿入」＞「モジュール」をクリックし、次のコードをモジュールウィンドウに貼り付けます。

VBAコード：数式からセル参照を抽出：

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. コードを貼り付けた後、コードを保存し、ワークシートに戻ります。そして、この数式を入力します：=extractcellrefs(G2)（G2は、セル参照を抽出したい数式が含まれているセルです）結果を得たいセルに入力し、 Enterキーを押します。すると、すべてのセル参照が数式から抽出されます。スクリーンショットをご覧ください：