Excelのワークシートから1つまたはすべてのグラフをPowerPointにエクスポートするにはどうすればよいですか？

場合によっては、特定の目的でExcelから1つのグラフやすべてのグラフをPowerPointにエクスポートする必要があるかもしれません。この記事では、その方法について説明します。

VBAコードを使用してExcelワークシートから単一のグラフまたはすべてのグラフをPowerPointにエクスポートする

VBAコードを使用してExcelワークシートから単一のグラフまたはすべてのグラフをPowerPointにエクスポートする

このセクションでは、ワークブックから単一のグラフまたはすべてのグラフをPowerPointにエクスポートするためのVBAコードを紹介します。以下の手順に従ってください。

1. AltキーとF11キーを同時に押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2. Microsoft Visual Basic for Applicationsウィンドウで、下のスクリーンショットのように「ツール」＞「参照設定」をクリックします。

3. 「参照設定 – VBAProject」ダイアログボックスで、下にスクロールして「Microsoft PowerPoint Object Library」オプションを探してチェックし、「OK」ボタンをクリックします。スクリーンショットをご覧ください：

4. 次に「挿入」＞「モジュール」をクリックします。

5. 単一のグラフをPowerPointにエクスポートしたい場合は、ワークシート内のグラフを選択し、Microsoft Visual Basic for Applicationsウィンドウに戻り、以下のVBAコードをコピーしてモジュールウィンドウに貼り付けてください。

VBAコード: Excelワークシートから単一のグラフをPowerPointにエクスポート

Sub SingleActiveChartToPowerPoint_EarlyBinding1()
'Updated by Extendoffice 2017/9/15
  Dim pptApp As PowerPoint.Application
  Dim pptPres As PowerPoint.Presentation
  Dim pptSlide As PowerPoint.Slide
  Dim pptShape As PowerPoint.Shape
  Dim pptShpRng As PowerPoint.ShapeRange
  Dim xActiveSlideNow As Long
  On Error Resume Next
  If ActiveChart Is Nothing Then
    MsgBox "Select a chart and try again!", vbExclamation, "KuTools For Excel"
    Exit Sub
  End If
  Set pptApp = GetObject(, "PowerPoint.Application")
  If pptApp Is Nothing Then
    Set pptApp = CreateObject("PowerPoint.Application")
    Set pptPres = pptApp.Presentations.Add
    Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
  Else
    If pptApp.Presentations.Count > 0 Then
      Set pptPres = pptApp.ActivePresentation
      If pptPres.Slides.Count > 0 Then
        xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
        Set pptSlide = pptPres.Slides(xActiveSlideNow)
      Else
        Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
      End If
    Else
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    End If
  End If
  ActiveChart.ChartArea.Copy
  With pptSlide
    .Shapes.Paste
    Set pptShape = .Shapes(.Shapes.Count)
    Set pptShpRng = .Shapes.Range(pptShape.Name)
  End With
  With pptShpRng
    .Align msoAlignCenters, True
    .Align msoAlignMiddles, True
  End With
  pptShpRng.Select
End Sub

ワークブック内のすべてのグラフをエクスポートしたい場合は、以下のVBAコードをコピーしてモジュールウィンドウに貼り付けてください。

VBAコード: ExcelワークシートからすべてのグラフをPowerPointにエクスポート

Option Explicit
'Updated by Extendoffice 2017/9/15
Dim pptApp As PowerPoint.Application
Dim pptPres As PowerPoint.Presentation
Dim pptSlide As PowerPoint.Slide
Dim pptSlideCount As Integer
Sub ChartsToPowerPoint()
    Dim xSheet As Worksheet
    Dim xChartsCount As Integer
    Dim xChart As Object
    Dim xActiveSlideNow As Integer
    On Error Resume Next
    For Each xSheet In ActiveWorkbook.Worksheets
        xChartsCount = xChartsCount + xSheet.ChartObjects.Count
    Next xSheet
    If xChartsCount = 0 Then
        MsgBox "Sorry, there are no charts to export!", vbCritical, "Ops"
        Exit Sub
    End If
    Set pptApp = GetObject(, "PowerPoint.Application")
    If pptApp Is Nothing Then
      Set pptApp = CreateObject("PowerPoint.Application")
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    Else
        If pptApp.Presentations.Count > 0 Then
          Set pptPres = pptApp.ActivePresentation
          If pptPres.Slides.Count > 0 Then
            xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
            Set pptSlide = pptPres.Slides(xActiveSlideNow)
          Else
            Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
          End If
        Else
          Set pptPres = pptApp.Presentations.Add
          Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
        End If
    End If
    For Each xSheet In ActiveWorkbook.Worksheets
        For Each xChart In xSheet.ChartObjects
            Call pptFormat(xChart.Chart)
        Next xChart
    Next xSheet
    For Each xChart In ActiveWorkbook.Charts
        Call pptFormat(xChart)
    Next xChart
    
    Set pptSlide = Nothing
    Set pptPres = Nothing
    Set pptApp = Nothing
    MsgBox "The charts were copied successfully to the new presentation!", vbInformation, "KuTools For Excel"
End Sub
Private Sub pptFormat(xChart As Chart)
    Dim xCharTiTle As String
    Dim I As Integer
    On Error Resume Next
    xCharTiTle = xChart.ChartTitle.Text
    xChart.ChartArea.Copy
    pptSlideCount = pptPres.Slides.Count
    Set pptSlide = pptPres.Slides.Add(pptSlideCount + 1, ppLayoutBlank)
    pptSlide.Select
    pptSlide.Shapes.PasteSpecial ppPasteJPG
    If xCharTiTle <> "" Then
        pptSlide.Shapes.AddTextbox msoTextOrientationHorizontal, 12.5, 20, 694.75, 55.25
    End If
    For I = 1 To pptSlide.Shapes.Count
        With pptSlide.Shapes(I)
            Select Case .Type
                Case msoPicture:
                    .Top = 87.84976
                    .left = 33.98417
                    .Height = 422.7964
                    .Width = 646.5262
                Case msoTextBox:
                    With .TextFrame.TextRange
                        .ParagraphFormat.Alignment = ppAlignCenter
                        .Text = xCharTiTle
                        .Font.Name = "Tahoma (Headings)"
                        .Font.Size = 28
                        .Font.Bold = msoTrue
                    End With
                End Select
        End With
    Next I
End Sub

6. F5キーを押すか「実行」ボタンをクリックしてコードを実行します。すると、選択したグラフまたはすべてのグラフがインポートされた新しいPowerPointが開きます。また、下のスクリーンショットのようなKutools for Excelダイアログボックスが表示されますので、「OK」ボタンをクリックしてください。

Kutools AIでExcelの魔法を解き放つ

• スマート実行: セル操作、データ分析、グラフ作成を簡単なコマンドで行います。
• カスタム数式: ワークフローを合理化するための独自の数式を生成します。
• VBAコーディング: 簡単にVBAコードを作成し実装します。
• 数式の解釈: 複雑な数式を簡単に理解できます。
• テキスト翻訳: スプレッドシート内の言語障壁を取り除きます。

AI搭載ツールでExcelの機能を強化しましょう。今すぐダウンロードして、かつてないほどの効率を体験してください！

関連記事：

• Excelで複数またはすべてのシートを個別のCSVまたはテキストファイルとして保存・エクスポートするにはどうすればよいですか？
• Excelで選択範囲またはすべてのテーブルをPDFとして保存するにはどうすればよいですか？