Excelで入力中にテキストボックスを自動補完するにはどうすればよいですか？

デフォルトでは、Excelは現在のワークシートのセルに入力した内容を記憶し、次回に関連する頭文字を新しいセルに入力するとその内容を自動補完します。しかし、ワークシートに入力したすべての内容をテキストボックス（ActiveXコントロール）で自動補完したい場合はどうすればよいでしょうか？この記事では、VBAを使用してテキストボックス内で頭文字を入力した際に自動補完する方法をご紹介します。

VBAコードを使用して入力中にテキストボックスを自動補完する

VBAコードを使用して入力中にテキストボックスを自動補完する

以下の手順に従って、テキストボックス内に頭文字を入力した際に自動補完されるように設定してください。

1. 開発 > 挿入 > テキストボックス（ActiveXコントロール）をクリックして、テキストボックスを挿入してください。スクリーンショットをご覧ください：

2. そして、開発 > 挿入 > リストボックス（ActiveXコントロール）をクリックして、リストボックスを現在のワークシートに挿入します。スクリーンショットをご覧ください：

3. シートタブを右クリックし、下のスクリーンショットに示すようにコンテキストメニューから「コードの表示」をクリックします。

4. Microsoft Visual Basic for Applicationsウィンドウで、以下のVBAコードをコピーしてコードウィンドウに貼り付けます。その後、ツール > 参照設定をクリックし、参照設定 – VBAProjectダイアログボックスで「Microsoft Scripting Runtime」のチェックボックスをオンにしてください。スクリーンショットをご覧ください：

VBAコード: 入力中にテキストボックスを自動補完する

Dim xRg As Range
Dim xDic As New Dictionary
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.TextBox1.Value = Me.ListBox1.Value
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xVal As String
    On Error Resume Next
    If IsNumeric(Target.Value) Then
        xVal = Str(Target.Value)
    Else
        xVal = Target.Value
    End If
    If xVal <> "" Then
        If Not xDic.Exists(xVal) Then
            xDic.Add xVal, xVal
        End If
    End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Me.ListBox1.Visible = False
End Sub
Private Sub Worksheet_Activate()
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    If xRg Is Nothing Then
        Set xRg = ActiveSheet.UsedRange
    End If
    Me.ListBox1.Visible = False
    xDic.RemoveAll
    With Me.ListBox1
        For I = 1 To xRg.Count
            xStr = xRg(I).Value
            If xStr <> "" Then
                .AddItem xStr
                If Not xDic.Exists(xStr) Then
                    xDic.Add xStr, xStr
                End If
            End If
        Next
    End With
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With Me.ListBox1
        .Top = Me.TextBox1.Top
        .Left = Me.TextBox1.Left + Me.TextBox1.Width
        .Width = Me.TextBox1.Width
    End With
    TextBoxVal Me.TextBox1.Object
End Sub
Sub TextBoxVal(xTextBox As Variant)
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    If xRg Is Nothing Then Exit Sub
    Me.ListBox1.Clear
    xStr = xTextBox.Value
    If xStr = "" Then
        Me.ListBox1.Visible = False
        Application.EnableEvents = True
        Exit Sub
    End If
    For I = 0 To UBound(xDic.Items)
        If Left(xDic.Items(I), Len(xStr)) = xStr Then
            Me.ListBox1.AddItem xDic.Items(I)
        End If
    Next
    Me.ListBox1.Visible = True
    If Me.ListBox1.ListCount > 0 Then
        With xTextBox
            .Value = Me.ListBox1.List(0)
            .SelStart = Len(xStr)
            .SelLength = Len(Me.ListBox1.List(0))
        End With
    End If
    Me.ListBox1.Activate
    Me.ListBox1.Selected(0) = True
    Application.ScreenUpdating = True
End Sub
Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Me.TextBox1.Value = Me.ListBox1.Value
    End If
End Sub

注釈: コード内のListBox1とTextbox1は、ワークシートに挿入したリストボックスとテキストボックスの名前です。

5. Alt + Qキーを押して、Microsoft Visual Basic for Applicationsウィンドウを終了します。

6. ワークシートの開発 > デザインモードをクリックして、デザインモードをオフにします。

7. 別のワークシートに切り替えてから、前のワークシートに戻ることでVBAコードが有効になります。

これで準備完了です。テキストボックスに頭文字を入力すると、ワークシートに入力した内容の中でその文字で始まるすべてのテキストが、テキストボックスの右側にあるリストボックスの中に表示されます。必要なものをダブルクリックして、テキストボックスに入力してください。スクリーンショットをご覧ください：

注釈: 上矢印または下矢印キーを使用してリストボックス内のすべての自動補完テキスト間を移動し、Enterキーを押して必要なものをテキストボックスに入力できます。

関連記事：

• Excelでテキストボックスを選択したときにそのテキストを自動選択するにはどうすればよいですか？
• Excelでテキストボックスをクリックしたときに内容をクリアするにはどうすればよいですか？
• Excelで複数のセルのテキストを連結してテキストボックスに表示するにはどうすればよいですか？
• Excelでテキストボックスの編集を無効にしてユーザー入力を防ぐにはどうすればよいですか？
• Excelでテキストボックスをパーセンテージ形式にするにはどうすればよいですか？