Excelの右クリックメニューから複数のマクロを実行するにはどうすればよいですか？

ワークブックに複数のvbaマクロがある場合は、VBAウィンドウを開き、コードを実行する必要があるときにマクロを選択する必要があります。 この記事では、左のスクリーンショットに示すように、右クリックメニューからマクロを実行して作業をより効率的にする方法について説明します。

VBAコードを使用して右クリックメニューから複数のマクロを実行する

VBAコードを使用して右クリックメニューから複数のマクロを実行する

右クリックメニューからブック内でマクロコードを実行するには、次の手順が役立つ場合があります。次のようにしてください。

1。 穴を開ける Altキー+ F11 キーを押して アプリケーション向け Microsoft Visual Basic 窓。

2。 次に、ダブルクリックします このワークブック 左側で プロジェクト ペインをクリックし、以下のVBAコードをコピーして空のモジュールに貼り付けます。

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3。 まだ アプリケーション向け Microsoft Visual Basic ウィンドウをクリックしてください インセット > モジュール、次のコードをこのモジュールに貼り付けます。

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4。 コードを貼り付けたら、 ツール > 参考情報、と 参考資料-VBAProject ダイアログボックスが表示されたら、チェックしてください Microsoft Visual Basic for Applications 拡張機能 5.3 内のオプション 利用可能な参考文献 リストボックス、スクリーンショットを参照：

5。 次に、をクリックします OK ダイアログを終了するには、このワークブックを次のように保存する必要があります。 Excelマクロが有効なブック フォーマット、スクリーンショットを参照してください：

6。 最後に、ワークブックを再起動してコードを有効にしてください。次に、セルを右クリックすると、 マクロを実行する オプションが右クリックメニューに挿入され、ワー​​クブック内のすべてのマクロが次のスクリーンショットのようにサブメニューに一覧表示されます。

7。 次に、クリックするだけでコードを実行できます。