Excel でネストされた IF 文をマスターする – ステップバイステップガイド

Excel では、IF 関数は基本的な論理テストに欠かせませんが、複雑な条件を扱う際には、データ処理を強化するためにネストされた IF 文が必要になることがよくあります。この包括的なガイドでは、構文から実践的な応用例まで、ネストされた IF の基本を詳しく解説します。また、AND や OR といった条件との組み合わせ方も紹介します。さらに、ネストされた IF 関数の可読性を高めるコツや使用時のヒントを共有するとともに、VLOOKUP や IFS など、複雑な論理演算をよりシンプルかつ効率的に実現できる強力な代替手段についても探ります。

• ネストされた IF の構文
• ネストされた IF の実用例
• AND/OR 条件を含むネストされた IF

• ネストされた IF を読みやすくする方法
• ネストされた IF 関数の順序
• 数値とテキストは別々に扱う必要があります
• ネストされた IF の制限事項

• VLOOKUP の使用
• IFS の使用
• CHOOSE と MATCH の使用

Excel の IF 関数とネストされた IF 文の比較

Excel の IF 関数とネストされた IF 文は目的が似ていますが、その複雑さと用途では大きく異なります。

ネストされた IF の使用方法

このセクションでは、Excel におけるネストされた IF 文の基本的な使い方を、その構文や実践的な例に加え、AND 条件および OR 条件との併用方法とともに解説します。

ネストされた IF の構文

関数の構文を正しく理解することは、Excel でその関数を的確かつ効果的に活用するための土台です。まずは、ネストされた IF 文の構文からマスターしましょう。

構文：

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

引数：

• 条件1、条件2、条件3：これらはテストしたい条件です。各条件は条件1から順に評価されます。
• 結果1：条件1 が TRUE の場合に返される値です。
• 結果2：条件1 が FALSE で条件2 が TRUE の場合に返される値です。ただし、結果2 は条件1 が FALSE の場合にのみ評価されることにご注意ください。
• 結果3：条件1 と条件2 の両方が FALSE で、かつ条件3 が TRUE の場合に返される値です。つまり、結果3 が評価されるには、条件1 と条件2 がいずれも FALSE である必要があります。
• 結果4 条件1、条件2、条件3 のすべてが FALSE の場合に返される結果です。
  
  簡単に言えば、この式は次のように解釈できます。
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

ネストされた IF 構造では、各後続の条件は、それまでのすべての条件が FALSE だった場合にのみ評価されることを覚えておきましょう。この順次チェックこそが、ネストされた IF の動作を理解するうえで非常に重要です。

ネストされた IF の実用例

それでは、ネストされた IF 関数の実用例を2 つご紹介しましょう。

例1：成績評価システム

以下のスクリーンショットのように、学生の得点リストがあり、その得点に基づいて成績を付与したいとします。このようなタスクにはネストされた IF を使用できます。

空白セル（この場合は C2）を選択し、次の数式を入力して Enter キーを押すと結果が得られます。その後、フィルハンドルを下にドラッグして残りの結果を取得してください。

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

例2：営業手当の計算

営業担当者が業績に応じて異なる手当率を受け取るシナリオを考えてみましょう。以下のスクリーンショットのように、さまざまな売上目標に基づいて営業担当者の手当を計算したい場合、ネストされた IF 文が役立ちます。

空白セル（この場合は C2）を選択し、次の数式を入力して Enter キーを押すと結果が得られます。その後、フィルハンドルを下にドラッグして残りの結果を取得してください。

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

AND/OR 条件を含むネストされた IF

このセクションでは、前述の最初の例「成績評価システム」を改良し、Excel でネストされた IF 関数を AND 条件または OR 条件と組み合わせる方法をご紹介します。改良版の成績評価例では、「出席率」に基づく追加条件を新たに導入しています。

AND 条件と組み合わせたネストされた IF の使用

学生が得点と出席率の両方の基準を満たした場合、成績が1 段階アップします。たとえば、得点が60 以上かつ出席率が95％以上であれば、A から A＋、B から B＋など、成績が1 ランク上がります。ただし、出席率が95％未満の場合は、元の得点に基づく評価基準が適用されます。このようなケースでは、AND 条件を含むネストされた IF 文を使用する必要があります。

空白セル（この場合は D2）を選択し、次の数式を入力して Enter キーを押すと結果が得られます。その後、フィルハンドルを下にドラッグして残りの結果を取得してください。

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

OR 条件と組み合わせたネストされた IF の使用

このケースでは、学生の得点が95 以上、または出席率が95% 以上の場合、成績が1 段階上がります。ネストされた IF と OR 条件を組み合わせてこれを実現する方法は次のとおりです。

空白セル（この場合は D2）を選択し、次の数式を入力して Enter キーを押すと結果が得られます。その後、フィルハンドルを下にドラッグして残りの結果を取得してください。

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

ネストされた IF のヒントとテクニック

このセクションでは、ネストされた IF 関数を活用するための4 つの便利なヒントとテクニックをご紹介します。

ネストされた IF を読みやすくする方法

典型的なネストされた IF 文は一見コンパクトに見えても、読み解くのが難しいことがあります。

次の数式では、特に複雑さが増すにつれて、一つの条件がどこで終わり、次の条件がどこから始まるのかを瞬時に把握することが難しくなります。

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

解決策：改行とインデントの追加

ネストされた IF を読みやすくするには、数式を複数行に分割し、各 IF 関数を改行で配置しましょう。数式内で IF の直前にカーソルを置き、Alt + Enter キーを押すだけです。

上記の数式を分割すると、次のように表示されます：

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

この形式により、各条件とその出力が明確に示され、数式の可読性がさらに向上します。

ネストされた IF 関数の順序

ネストされた IF 数式では、論理条件の順序が極めて重要です。なぜなら、その順序がExcel による条件の評価方法を決定し、最終的な数式の出力に直接影響を与えるからです。

正しい数式

成績評価システムの例では、得点に基づいて成績を割り当てるために以下の数式を使用しています。

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel はネストされた IF 数式の条件を、最初から最後まで順に評価します。この数式では、まず最高得点のしきい値（「A」のための>=90）をチェックし、その後、より低いしきい値へと進んでいきます。これにより、得点が該当する最高ランクの成績と比較されるようになります。最初の条件（A2>=90）が TRUE であれば、「A」を返し、それ以降の条件は一切評価されません。

順序が誤った数式

条件の順序を逆にして、最も低いしきい値から始めると、誤った結果が得られます。

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

この誤った数式では、得点95 が最初の条件「B2>=60」を即座に満たしてしまうため、「D」と誤って評価されてしまいます。

数値とテキストは別々に扱う必要があります

このセクションでは、ネストされた IF 文において、数値とテキストがどのように異なる扱いを受けるかを解説します。

数値

数値は算術比較や計算に使用されます。ネストされた IF 文では、「>」「=」「<=」などの演算子を使って、数値を直接比較できます。

テキスト

ネストされた IF 文では、テキストを二重引用符で囲む必要があります。次の数式中の A、B、C、D、F を参照してください：

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

ネストされた IF の制限事項

このセクションでは、ネストされた IF 関数の主な制限事項と欠点を紹介します。

複雑さと可読性：

Excel では最大64 個の IF 関数をネストできますが、実際にそれを行うことはまったく推奨されません。ネストのレベルが深くなるほど、数式は複雑さを増し、読みにくく、理解しにくく、保守も困難になります。

エラーが発生しやすい：

さらに、複雑にネストされた IF 文はエラーが発生しやすく、デバッグや修正が難しくなることがあります。

拡張やスケーリングが困難：

ロジックの変更やさらなる条件追加が必要になった際、深くネストされた IF 文は修正や拡張が困難になります。

これらの制限を理解することが、Excel でネストされた IF 文を効果的に活用する鍵です。多くの場合、ネストされた IF を他の関数と組み合わせたり、代替アプローチを検討したりすることで、より効率的でメンテナンスしやすいソリューションが実現できます。

ネストされた IF の代替手段

このセクションでは、ネストされた IF 文の代わりに使用できるExcel のいくつかの関数を紹介します。

VLOOKUP の使用

前述の2 つの実践例を、ネストされた IF 文の代わりに VLOOKUP 関数を使って実現できます。その方法は次のとおりです：

例1：VLOOKUP を使った成績評価システム

ここでは、VLOOKUP を使って得点から成績を自動で割り当てる方法をご紹介します。

ステップ1：成績用の検索テーブルを作成する

まず、得点範囲と対応する成績の検索テーブル（この場合は E1:F6 など）を作成する必要があります。注：テーブルの最初の列に記載する得点は、昇順に並べる必要があります。

ステップ2：VLOOKUP 関数を適用して成績を割り当てる

空白セル（この場合は C2）を選択し、次の数式を入力して Enter キーを押すと最初の成績が得られます。この数式セルを選択し、フィルハンドルを下にドラッグして残りの成績を取得してください。

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

例2：VLOOKUP を使った営業手当の計算

Excel で営業手当の計算を VLOOKUP を使って実現することもできます。以下の手順に従ってください。

ステップ 1：成績用の検索テーブルを作成する

まず、売上と対応する手当率の検索テーブル（例：E2:F4）を作成する必要があります。注：テーブルの最初の列の売上は、昇順に並べる必要があります。

ステップ 2：成績の割り当てに VLOOKUP 関数を適用する

空白セル（この例では C2）を選択し、次の数式を入力して Enter キーを押すと、最初のコミッションが表示されます。この数式が入ったセルを選択してフィルハンドルを下にドラッグすれば、残りの結果も自動的に得られます。

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

IFS の使用

IFS 関数はネストの必要性をなくして処理を簡素化し、数式を読みやすく管理しやすくします。これにより可読性が向上し、複数の条件分岐を効率的に扱えるようになります。IFS 関数を使用するには、Excel 2019 以降、または Office 365 サブスクリプションをご利用ください。以下で、その実用的な使用例をご紹介します。

例 1：IFS による成績評価システム

前述と同じ評価基準を前提として、IFS 関数は次のように使用できます。

空白セル（例：C2）を選択して次の数式を入力し、Enter キーを押すと、最初の結果が表示されます。この結果セルを選択し、フィルハンドルを下にドラッグすれば、残りの結果も簡単に取得できます。

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

例 2：IFS による営業手数料計算

営業手数料計算のシナリオでは、IFS 関数を次のように適用します。

空白セル（例：C2）を選択し、次の数式を入力して Enter キーを押すと、最初の結果が表示されます。この結果セルを選択し、フィルハンドルを下にドラッグすると、残りの結果が得られます。

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

CHOOSE と MATCH の使用

CHOOSE 関数と MATCH 関数を組み合わせる方法は、ネストされた IF 文と比べてより効率的で管理しやすい場合があります。この方法により数式が簡潔になり、更新や変更も容易になります。以下では、この記事で紹介する2 つの実用例に CHOOSE 関数と MATCH 関数を組み合わせて使用する方法を説明します。

例 1：CHOOSE と MATCH による成績評価システム

CHOOSE 関数と MATCH 関数を組み合わせれば、スコアに応じて簡単に成績を割り当てられます。

ステップ 1：検索値を用いた検索配列の作成

まず、MATCH 関数が検索対象とするしきい値を含むセル範囲（この例では$E$2：$E$6）を指定する必要があります。注：近似一致を使用する場合、MATCH 関数が正しく動作するには、この範囲内の数値を昇順に並べ替えておく必要があります。

ステップ 2：CHOOSE と MATCH を用いて成績を割り当てる

空白セル（この例では C2）を選択し、次の数式を入力して Enter キーを押すと、最初の成績が表示されます。この数式セルを選択し、フィルハンドルを下にドラッグすると、残りの結果が得られます。

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

例 2：IFS による営業手数料計算

営業手数料の計算には、CHOOSE 関数と MATCH 関数を組み合わせる方法も非常に効果的です。特に、手数料率が特定の売上しきい値に基づいている場合にその真価を発揮します。以下で、その具体的な活用法をご紹介します。

ステップ 1：検索値を用いた検索配列の作成

まず、MATCH 関数が検索対象とするしきい値を含むセル範囲（この例では$E$2：$E$4）を作成する必要があります。注：近似一致を使用する場合、MATCH 関数が正しく動作するには、この範囲内の数値を昇順に並べておく必要があります。

ステップ 2：CHOOSE と MATCH を用いて結果を取得する

空白セル（この例では C2）を選択し、次の数式を入力して Enter キーを押すと、最初の成績が表示されます。この数式セルを選択し、フィルハンドルを下にドラッグすると、残りの結果が得られます。

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

結論として、Excel でネストされた IF 文をマスターすることは、データ分析や意思決定の場面で複雑な論理シナリオを効果的に扱うための非常に価値あるスキルです。ネストされた IF 文は複雑な条件分岐に強力な一方で、その制限にも十分注意する必要があります。特定の状況では、VLOOKUP や IFS、あるいは CHOOSE と MATCH の組み合わせといったよりシンプルな代替手段が、より効率的な解決策となる場合もあります。こうした知見を活かせば、今後、皆様はデータ分析タスクに最も適したExcel テクニックを自信を持って選び、スプレッドシートの明確性・正確性・効率性をしっかりと確保できるようになります。さらにExcel の機能を深く学びたい方のために、当社ウェブサイトでは豊富なチュートリアルをご用意しています。こちらでさらに多くのExcel のヒントとテクニックをご覧ください。

関連記事