Excel では、IF 関数は基本的な論理テストに不可欠ですが、複雑な条件では、データ処理を強化するために入れ子になった IF ステートメントが必要になることがよくあります。この包括的なガイドでは、入れ子になった IF と AND/OR 条件の組み合わせなど、構文から実際の応用まで、入れ子になった IF の基本を詳しく説明します。さらに、入れ子になった IF 関数の読みやすさを向上させる方法と入れ子になった IF に関するヒントを共有し、複雑な論理演算を使いやすく効率的にするための VLOOKUP や IFS などの強力な代替手段を検討します。

• 入れ子になった IF の構文
• 入れ子になった IF の実践例
• AND / OR 条件を使用したネストされた if

• ネストされた IF を読みやすくする
• ネストされた IF 関数の順序
• 数字とテキストは別の方法で扱う必要があります
• 入れ子になった IF の制限事項

• VLOOKUPの使用
• IFSの使用
• 選択と一致の使用

Excel IF 関数と入れ子になった IF ステートメント

Excel の IF 関数と入れ子になった IF ステートメントは同様の目的を果たしますが、複雑さと用途が大きく異なります。

ネストされた IF の使用法

このセクションでは、Excel での入れ子になった IF ステートメントの基本的な使用法 (構文、実践的な例、AND または OR 条件との使用方法など) を説明します。

入れ子になった IF の構文

関数の構文を理解することは、関数を Excel で正しく効果的に適用するための基礎です。ネストされた if ステートメントの構文から始めましょう。

構文:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Arguments:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

ネストされた IF 構造では、後続の各条件は、前の条件がすべて FALSE の場合にのみ評価されることに注意してください。この順次チェックは、入れ子になった IF がどのように機能するかを理解するために重要です。

入れ子になった IF の実践例

ここで、2 つの実際的な例を使用して、入れ子になった IF の使用法を詳しく見てみましょう。

例 1: 評価システム

以下のスクリーンショットに示すように、学生のスコアのリストがあり、これらのスコアに基づいて成績を割り当てたいとします。ネストされた IF を使用して、このタスクを実行できます。

空白のセル（この場合はC2）を選択し、次の数式を入力して を押します。 入力します 結果を得るために。次に、 フィルハンドル 残りの結果を取得するには、ダウンします。

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

例 2: 販売手数料の計算

営業担当者が販売実績に基づいて異なる手数料率を受け取るシナリオを想像してください。以下のスクリーンショットに示されているように、これらのさまざまな売上しきい値に基づいて営業担当者のコミッションを計算したいと考えており、ネストされた IF ステートメントがこれに役立ちます。

空白のセル（この場合はC2）を選択し、次の数式を入力して を押します。 入力します 結果を得るために。次に、 フィルハンドル 残りの結果を取得するには、ダウンします。

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

AND / OR 条件を使用したネストされた if

このセクションでは、上記の最初の例「評価システム」を変更して、Excel でネストされた IF と AND または OR 条件を組み合わせる方法を示します。改訂された採点例では、「出席率」に基づく追加条件を導入しました。

ネストされた if と AND 条件の使用

学生がスコアと出席基準の両方を満たしている場合、成績が上がります。たとえば、スコアが 60 以上で、出席率が 95% 以上の生徒の成績は、A から A+、B から B+ のように 95 段階上がります。ただし、出席率が XNUMX% 未満の場合、採点は元のスコアベースの基準に従います。このような場合は、AND 条件を含むネストされた IF ステートメントを使用する必要があります。

空白のセル（この場合はD2）を選択し、次の数式を入力して を押します。 入力します 結果を得るために。次に、 フィルハンドル 残りの結果を取得するには、ダウンします。

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

ネストされた if と OR 条件の使用

この場合、得点が95点以上、または出席率が95％以上の場合に成績がXNUMX段階上がります。ネストされた IF 条件と OR 条件を使用してこれを実現する方法を次に示します。

空白のセル（この場合はD2）を選択し、次の数式を入力して を押します。 入力します 結果を得るために。次に、 フィルハンドル 残りの結果を取得するには、ダウンします。

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

ネストされた IF に関するヒントとコツ

このセクションでは、ネストされた IF に関する 4 つの役立つヒントとテクニックについて説明します。

ネストされた IF を読みやすくする

一般的なネストされた IF ステートメントはコンパクトに見えますが、解読するのが難しい場合があります。

次の式では、特に複雑さが増すにつれて、1 つの条件がどこで終わり、別の条件が始まるのかをすぐに特定することが困難になります。

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

解決策: 改行とインデントを追加する

ネストされた IF を読みやすくするには、式を複数の行に分割し、ネストされた IF をそれぞれ新しい行に配置します。数式では、IF の前にカーソルを置き、Alt + Enter キーを押すだけです。

上記の式を分解すると、次のようになります。

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

この形式により、各条件と対応する出力がどこにあるのかが明確になり、数式の読みやすさが向上します。

ネストされた IF 関数の順序

入れ子になった IF 数式内の論理条件の順序は、Excel によるこれらの条件の評価方法を決定し、数式の最終結果に影響を与えるため、非常に重要です。

正しい式

評価システムの例では、次の式を使用してスコアに基づいて評価を割り当てます。

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel は、入れ子になった IF 式の条件を最初の条件から最後の条件まで順番に評価します。この式は、最初に最高スコアのしきい値 (「A」の場合は >=90) をチェックし、次に低いしきい値に移動します。これにより、スコアが資格のある最高のグレードと比較されることが保証されます。最初の条件が true (A2>=90) の場合、「A」を返し、それ以降の条件は評価されません。

間違った順序の式

条件の順序が逆で、最も低いしきい値から始まると、誤った結果が返されます。

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

この誤った式では、スコア 95 はすぐに最初の条件 B2>=60 を満たし、誤ってグレード「D」が割り当てられます。

数字とテキストは別の方法で扱う必要があります

このセクションでは、ネストされた IF ステートメントで数値とテキストがどのように異なる扱いを受けるかを説明します。

数字

数値は算術比較と計算に使用されます。ネストされた IF ステートメントでは、>、<、=、>=、<= などの演算子を使用して数値を直接比較できます。

テキスト

ネストされた IF ステートメントでは、テキストは次のようにする必要があります。 二重引用符で囲まれる。次の式の A、B、C、D、F を参照してください。

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

入れ子になった IF の制限事項

このセクションでは、ネストされた IF のいくつかの制限と欠点をリストします。

複雑さと読みやすさ:

Excel では最大 64 個の異なる IF 関数をネストできますが、これはまったくお勧めできません。ネストのレベルが増えるほど、式はより複雑になります。これにより、数式が読みにくく、理解しにくく、保守しにくくなる可能性があります。

エラーを起こしやすい：

さらに、複雑にネストされた IF ステートメントはエラーが発生しやすくなり、デバッグや変更が困難になる可能性があります。

拡張またはスケーリングが難しい:

ロジックが変更された場合、またはさらに条件を追加する必要がある場合、深くネストされた IF は変更または拡張するのが難しい場合があります。

Excel でネストされた IF ステートメントを効果的に使用するには、これらの制限を理解することが重要です。多くの場合、ネストされた IF を他の関数と組み合わせたり、代替アプローチを模索したりすると、より効率的で保守可能なソリューションが得られます。

入れ子になった IF の代替手段

このセクションでは、入れ子になった IF ステートメントの代わりに使用できる Excel の関数をいくつかリストします。

VLOOKUPの使用

入れ子になった IF ステートメントの代わりに VLOOKUP 関数を使用すると、上記の 2 つの実際的な例を実現できます。その方法は次のとおりです。

例 1: VLOOKUP を使用した評価システム

ここでは、VLOOKUP を使用してスコアに基づいて成績を割り当てる方法を説明します。

ステップ 1: グレードのルックアップ テーブルを作成する

まず、スコア範囲と対応する成績のルックアップ テーブル (この場合は E1:F6 など) を作成する必要があります。 Note: 表の最初の列のスコアは昇順でソートする必要があります。

ステップ 2: VLOOKUP 関数を適用して成績を割り当てる

空白のセル（この場合はC2）を選択し、次の数式を入力して、 入力します 初級取得の鍵。この数式セルを選択し、ドラッグします。 フィルハンドル 残りの成績を取得するにはダウンしてください。

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

例 2: VLOOKUP を使用した販売手数料の計算

VLOOKUP を使用して、Excel で販売手数料の計算を行うこともできます。以下のようにしてください。

ステップ 1: グレードのルックアップ テーブルを作成する

まず、売上と対応する手数料率のルックアップ テーブル (この場合は E2:F4 など) を作成する必要があります。 Note: テーブルの最初の列の売上は昇順で並べ替える必要があります。

ステップ 2: VLOOKUP 関数を適用して成績を割り当てる

空白のセル (この場合は C2) を選択し、次の数式を入力して Enter キーを押し、最初の手数料を取得します。この数式セルを選択し、フィル ハンドルを下にドラッグして残りの結果を取得します。

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

IFSの使用

　 IFS 関数 ネストの必要性を排除することでプロセスを簡素化し、数式を読みやすく管理しやすくします。これにより、可読性が向上し、複数の条件チェックの処理が合理化されます。 IFS 機能を利用するには、Excel 2019 以降を使用しているか、Office 365 サブスクリプションを持っていることを確認してください。実際の例でどのように適用できるかを見てみましょう。

例 1: IFS を使用した評価システム

以前と同じ採点基準を仮定すると、IFS 関数は次のように使用できます。

C2 などの空白のセルを選択し、次の数式を入力して を押します。 入力します 最初の結果を得るために。この結果セルを選択し、ドラッグします。 フィルハンドル 残りの結果を取得するには、ダウンします。

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

例 2: IFS を使用した販売手数料の計算

販売手数料計算シナリオでは、IFS 関数が次のように適用されます。

C2 などの空白のセルを選択し、次の数式を入力して を押します。 入力します 最初の結果を得るために。この結果セルを選択し、ドラッグします。 フィルハンドル 残りの結果を取得するには、ダウンします。

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

選択と一致の使用

CHOOSE および MATCH アプローチは、ネストされた IF ステートメントと比較して、より効率的で管理が容易です。この方法により、式が簡素化され、更新や変更がより簡単になります。以下では、CHOOSE 関数と MATCH 関数を組み合わせて使用​​して、この記事の 2 つの実際の例を処理する方法を示します。

例 1: CHOOSE と MATCH による評価システム

CHOOSE 関数と MATCH 関数を組み合わせて使用​​すると、さまざまなスコアに基づいて成績を割り当てることができます。

ステップ 1: 検索値を含むルックアップ配列を作成する

まず、MATCH が検索するしきい値を含むセル範囲を作成する必要があります (この場合は $E$2:$E$6 など)。 Note: 近似一致タイプを使用する場合に MATCH 関数が正しく機能するには、この範囲の数値を昇順で並べ替える必要があります。

ステップ 2: CHOOSE と MATCH を適用してグレードを割り当てる

空白のセル（この場合はC2）を選択し、次の数式を入力して、 入力します 初級取得の鍵。この数式セルを選択し、ドラッグします。 フィルハンドル 残りの結果を取得するには、ダウンします。

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

例 2: IFS を使用した販売手数料の計算

販売手数料の計算に CHOOSE と MATCH の組み合わせを使用することも、特に手数料率が指定された販売しきい値に基づいている場合に効果的です。どうすればよいか見てみましょう。

ステップ 1: 検索値を含むルックアップ配列を作成する

まず、MATCH が検索するしきい値を含むセル範囲を作成する必要があります (この場合は $E$2:$E$4 など)。 Note: 近似一致タイプを使用する場合に MATCH 関数が正しく機能するには、この範囲の数値を昇順で並べ替える必要があります。

ステップ 2: CHOOSE と MATCH を適用して結果を取得します

空白のセル（この場合はC2）を選択し、次の数式を入力して、 入力します 初級取得の鍵。この数式セルを選択し、ドラッグします。 フィルハンドル 残りの結果を取得するには、ダウンします。

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

結論として、Excel で入れ子になった IF ステートメントをマスターすることは、データ分析や意思決定プロセスにおける複雑な論理シナリオを処理する能力を強化する貴重なスキルです。ネストされた IF は複雑な論理演算に強力ですが、その制限事項に注意することが重要です。 VLOOKUP、IFS、CHOOSE with MATCH などのより単純な代替手段を使用すると、特定のシナリオでより合理的なソリューションを提供できます。これらの洞察を活用すれば、自信を持って最も適切な Excel テクニックをデータ分析タスクに適用して、スプレッドシートの明瞭さ、正確さ、効率性を確保できるようになります。 Excel の機能をさらに詳しく知りたい人のために、当社の Web サイトには豊富なチュートリアルが用意されています。 Excel のヒントとテクニックの詳細については、こちらをご覧ください.

関連記事