Outlook でフォルダ一覧を取得するにはどうすればよいですか？

作業中には、ナビゲーション内のすべてのメールフォルダ（ユーザーが作成した個人用フォルダを含む）をツリー構造で表示すると、Outlook ユーザーにとって非常に役立ちます。フォルダのツリー構造全体を素早く一覧表示するには、VBA コードを利用できます。このチュートリアルでは、VBA コードを使ってフォルダ一覧を簡単に取得する方法を学べます。

VBA コードでOutlook のフォルダ一覧を取得する

---

VBA コードでOutlook のフォルダ一覧を取得する

VBA コードでOutlook のフォルダ一覧を取得するには、以下の手順に従ってください。

1．キーボードで「Alt」＋「F11」を押して、「Microsoft Visual Basic for Applications」ウィンドウを開きます。

2．次に、「Project1」＞「Microsoft Outlook オブジェクト」＞「ThisOutlookSession」をダブルクリックして、「Project1 – ThisOutlookSession」ウィンドウを開いてください。スクリーンショットをご参照ください。

3．次に、以下の VBA コードを「Project1 – ThisOutlookSession」ウィンドウにコピー＆ペーストしてください。

VBA：Outlook でフォルダ一覧を取得する

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4．キーボードの「F5」キーを押して、VBA コードの実行を開始します。

5．「マクロ」ダイアログボックスが表示されたら、「実行」ボタンをクリックしてください。

6．マクロの実行が完了するまでお待ちください。その後、すべてのメールフォルダの一覧が新しいメッセージウィンドウに即座に表示されます。この一覧は簡単に印刷可能で、スクリーンショットもご参照ください。

注記：この VBA コードは、Outlook 2007、2010、および2013 でご利用いただけます。