Outlook カレンダーで予定の件名を検索・置換するには、どうすればよいですか？

検索と置換 Outlook カレンダー内の予定の件名を一括で同じテキストに置き換えたい場合や、Outlook にデータをインポートした後に件名フィールドに含まれる「Copy」という単語を一括で置き換えたい場合に便利です。この記事では、複数の予定の件名を検索・置換するための VBA コードをご紹介します。詳しくは、以下をご覧ください。

VBA コードで予定の件名を検索・置換する

---

VBA コードで予定の件名を検索・置換する

このセクションでは、以下の手順に従って VBA コードを使い、予定の件名を検索・置換できます。

1。まず、Outlook のマクロ設定を「低」に変更する必要があります。

1) Outlook 2010 および2013 では、「ファイル」＞「オプション」をクリックします。「Outlook のオプション」ダイアログボックスで、左側のメニューから「トラストセンター」を選択し、「トラストセンターの設定」ボタンをクリックします。

「トラストセンター」ダイアログボックスで、左側のバーから「マクロの設定」をクリックし、「マクロの設定」セクションで「すべてのマクロを有効にする」オプションを選択してください。「OK」ボタンをクリックします。スクリーンショットをご参照ください。

2) Outlook 2007 では、「ツール」＞「トラストセンター」をクリックします。「トラストセンター」ダイアログボックスの左側のバーから「マクロの設定」を選び、「マクロに対するセキュリティチェックを行わない」オプションを選択して、「OK」をクリックします。

2。「Alt」＋「F11」キーを押して、「Microsoft Visual Basic for Applications」ウィンドウを開きましょう。

3。「Microsoft Visual Basic for Applications」ウィンドウで、「プロジェクト1」＞「Microsoft Outlook オブジェクト」＞「ThisOutlookSession」をダブルクリックして展開し、VBA エディターを開いてください。スクリーンショットをご参照ください。

4。次の VBA コードを VBA エディターにコピー＆ペーストし、「F5」キーを押して実行してください。

VBA： 検索と置換予定の件名

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5。コードを実行すると、「Microsoft Outlook」ダイアログボックスが表示されるので、「OK」ボタンをクリックしてください。

6。2 つ目の「Microsoft Outlook」ダイアログボックスで、置き換えるテキストを入力し、「OK」ボタンをクリックします。

7。3 つ目の「Microsoft Outlook」ダイアログボックスで、置き換えるテキストを入力し、「OK」をクリックします。

注：指定したカレンダーの件名から「Copy」をすべて削除する場合は、このボックスを空白のままにしてください。

8。下記のダイアログボックスで［OK］ボタンをクリックしてください。

9。「フォルダーの選択」ダイアログボックスで、指定したメールアカウント配下のカレンダーを選択し、「OK」をクリックしてください。スクリーンショットをご参照ください。

10。その後、「置き換えが成功しました」というダイアログボックスが表示されるので、「OK」ボタンをクリックしてください。

11。これにより、選択したカレンダー内のすべての件名が新しい内容に一括で置き換えられます。