Outlookで予定や会議に費やした時間/日数/週数をカウントするにはどうすればよいですか？

Author: Kelly Last Modified: 2025-08-06

Outlookのカレンダーに多くの予定と会議があるとします。そして、これらの予定や会議に費やした時間/日数/週数をカウントしたいのですが、何かアイデアはありますか？この記事では、それを支援するためのVBAを紹介します。

VBAを使用して予定または会議に費やした時間/日数/週数をカウントする

VBAを使用して予定または会議に費やした時間/日数/週数をカウントする

この方法では、指定された予定や会議に費やした時間や分をカウントするためのVBAを紹介します。以下の手順を行ってください：

1. カレンダーフォルダーに切り替え、時間を計測したい予定または会議を選択します。

2. Alt + F11キーを同時に押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

3. 「挿入」>「モジュール」をクリックし、開いたモジュールウィンドウに以下のVBAコードを貼り付けます。

VBA: Outlookで予定または会議に費やした時間/分をカウントする

Sub CountTimeSpent()
Dim oOLApp As Outlook.Application
Dim oSelection As Outlook.Selection
Dim oItem As Object
Dim iDuration As Long
Dim iTotalWork As Long
Dim iMileage As Long
Dim iResult As Integer
Dim bShowiMileage As Boolean

bShowiMileage = False

iDuration = 0
iTotalWork = 0
iMileage = 0

On Error Resume Next

    Set oOLApp = CreateObject("Outlook.Application")
Set oSelection = oOLApp.ActiveExplorer.Selection

    For Each oItem In oSelection
If oItem.Class = olAppointment Then
iDuration = iDuration + oItem.Duration
iMileage = iMileage + oItem.Mileage
ElseIf oItem.Class = olTask Then
iDuration = iDuration + oItem.ActualWork
iTotalWork = iTotalWork + oItem.TotalWork
iMileage = iMileage + oItem.Mileage
ElseIf oItem.Class = Outlook.olJournal Then
iDuration = iDuration + oItem.Duration
iMileage = iMileage + oItem.Mileage
Else
iResult = MsgBox("Please select some Calendar, Task or Journal items at first!", vbCritical, "Items Time Spent")
Exit Sub
End If
Next

Dim MsgBoxText As String
MsgBoxText = "Total time spent: " & vbNewLine & iDuration & " minutes"

If iDuration > 60 Then
MsgBoxText = MsgBoxText & HoursMsg(iDuration)
End If

If iTotalWork > 0 Then
MsgBoxText = MsgBoxText & vbNewLine & vbNewLine & "Total work recorded; " & vbNewLine & iTotalWork & " minutes"

If iTotalWork > 60 Then
MsgBoxText = MsgBoxText & HoursMsg(iTotalWork)
End If
End If

If bShowiMileage = True Then
MsgBoxText = MsgBoxText & vbNewLine & vbNewLine & "Total iMileage; " & iMileage
End If

    iResult = MsgBox(MsgBoxText, vbInformation, "Items Time spent")

ExitSub:
Set oItem = Nothing
Set oSelection = Nothing
Set oOLApp = Nothing
End Sub

Function HoursMsg(TotalMinutes As Long) As String
Dim iHours As Long
Dim iMinutes As Long
iHours = TotalMinutes \ 60
iMinutes = TotalMinutes Mod 60
HoursMsg = " (" & iHours & " Hours and " & iMinutes & " Minutes)"
End Function

4. F5 キーを押すか、実行ボタンをクリックして、このVBAを実行します。

これでダイアログボックスが表示され、選択した予定/会議に費やした時間/分数が表示されます。スクリーンショットをご覧ください：