Outlook でフォルダーとサブフォルダーのリストをエクスポートして印刷するには、どうすればよいですか？

一般的に、「Ctrl」キーと「6」キーを押すと、Outlook のナビゲーションウィンドウにすべてのフォルダー一覧が表示されます。ただし、このフォルダーリストを直接印刷することはできません。本記事では、Outlook のすべてのフォルダーとそのサブフォルダーの一覧をエクスポートして印刷するための2 つの VBA スクリプトをご紹介します。

• Outlook のすべてのフォルダーとそのサブフォルダーの一覧を新規メールにエクスポートし、印刷できます。
• Outlook のすべてのフォルダーとそのサブフォルダーの一覧をメモ帳にエクスポートして、印刷できます。

---

Outlook のすべてのフォルダーとそのサブフォルダーの一覧を新規メールにエクスポートし、印刷できます。

この方法では、指定したメールアカウントのすべてのフォルダーとそのサブフォルダーを一覧化し、Outlook 内の新規メールにエクスポートする VBA スクリプトをご紹介します。その後、フォルダーリストを簡単に印刷できます。

1。「Alt」＋「F11」を押して、Microsoft Visual Basic for Applications ウィンドウを開きます。

2。「挿入」＞「標準モジュール」をクリックし、表示される新しいモジュールウィンドウに次の VBA コードを貼り付けてください。

VBA：Outlook の新規メール内のフォルダーとサブフォルダーのリストをエクスポートする

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3。「F5」キーを押して、VBA を実行しましょう。

4。表示された「フォルダーの選択」ダイアログボックスで、リストを印刷したいメールアカウントを選んで「OK」をクリックします。

5。選択したアカウントのフォルダーリストが、下図のように新規メールにコピーされます。「ファイル」＞「印刷」をクリックして、フォルダーリストを印刷してください。

6。印刷後、新規メールを保存せずに閉じます。

---

Outlook のすべてのフォルダーとそのサブフォルダーの一覧をメモ帳にエクスポートして、印刷できます。

この方法では、指定したメールアカウントのすべてのフォルダーとそのサブフォルダーをOutlook からメモ帳にエクスポートする VBA スクリプトをご紹介します。エクスポート後は、フォルダーリストを簡単に印刷できます。

1。「Alt」＋「F11」を押して、Microsoft Visual Basic for Applications ウィンドウを開きます。

2. 「挿入」＞「標準モジュール」をクリックし、開いた新しいモジュールウィンドウに次の VBA コードを貼り付けてください。

VBA：Outlook のすべてのフォルダーとサブフォルダーのリストをOutlook からメモ帳にエクスポートする

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3。「F5」キーを押して VBA を実行します。表示される「フォルダーの選択」ダイアログボックスで、エクスポートおよび印刷したいフォルダーリストが含まれるメールアカウントを選択し、「OK」をクリックしてください。

4。「フォルダーツリー出力」ダイアログボックスが表示されます。ツリーのインデントを含めるかどうかを選択し、「はい」または「いいえ」をクリックしてください。

これにより、「Outlook-Folders」という名前のテキストファイルがデスクトップに作成され、下図のように保存されます。

5。新しく作成されたテキストファイルをダブルクリックして開き、「ファイル」＞「印刷」をクリックし、エクスポートされたOutlook フォルダーのリストを印刷します。

関連記事

Outlook でフォルダーリストビューを表示または非表示にする