Outlook でメールメッセージを画像形式（JPG/TIFF）で保存するには、どうすればよいですか？

Outlook でメールメッセージを JPG や TIFF などの画像形式で保存しようとしたことはありますか？この記事では、その問題を解決する方法をご紹介します。

VBA コードでメールメッセージを画像形式として保存する

---

VBA コードでメールメッセージを画像形式として保存する

Outlook でメールメッセージを画像形式で保存するには、以下の手順に従ってください。

1．画像として保存したいメールを選択し、Alt＋F11キーを同時に押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2．Microsoft Visual Basic for Applicationsウィンドウで、挿入＞ユーザーフォームをクリックしてください。下図をご参照ください：

3．下図のようにユーザーフォームを作成してください。

4．JPG オプションボタンを選択し、左側のopbJPGという名前に変更します。この操作はプロパティペインで行います。

5．上記の手順を繰り返して、他のオプションボタンをopbTIFFに名前変更します。また、OKコマンドボタンおよびキャンセルコマンドボタンは、それぞれcdbOkおよびcdbCancelに名前変更してください。

注：プロパティペインがMicrosoft Visual Basic for Applicationsウィンドウに表示されていない場合は、F4キーを押して表示してください。

6．ユーザーフォームの空白部分をダブルクリックしてコードウィンドウを開き、表示されたすべてのコードを以下の VBA スクリプトに置き換えてください。その後、コードウィンドウを閉じます。

VBA コード1：メールメッセージを画像として保存する

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7．UserForm1を選択し、プロパティペインで下図のようにFrmPicTypeに名前を変更します。

8．挿入＞モジュールをクリックして、以下の VBA コードをモジュールウィンドウにコピーしてください。

VBA コード2：メールメッセージを画像として保存する

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9．ツール＞参照をクリックし、Microsoft PowerPoint オブジェクトライブラリのチェックボックスをオンにしてから、OKボタンをクリックしてください。下図をご参照ください：

10．F5キーを押してコードを実行すると、UserForm1ダイアログボックスが表示されます。画像形式を選択して、OKボタンをクリックしてください。下図をご参照ください：

11．フォルダーの参照ダイアログボックスで、画像を保存するフォルダーを指定して、OKボタンをクリックします。

12．最後に、Microsoft Outlookのダイアログボックスが表示され、保存が完了したことをお知らせします。OKボタンをクリックしてください。

これで、選択したメールが JPG または TIFF 画像に変換され、指定されたフォルダーに正常に保存されました。

---

関連記事：

• Outlook で複数のメールに含まれるすべての添付ファイルをフォルダーに保存するには、どうすればよいですか？
• Outlook でメールからすべての添付ファイルを削除するにはどうすればよいですか？