Outlook でメール本文にすべての受信者の名前を挿入するには、どうすればよいですか？

Outlook でメールを作成する際、すべての受信者の名前をメッセージ本文に挿入しなければならないことがあります。もちろん、一つひとつ手動でコピー＆ペーストすることも可能ですが、受信者が数十人もいると、その作業は非常に面倒です。本記事では、Outlook でこの手間を簡単に解消する方法をご紹介します。

Outlook で VBA コードを使用してメール本文にすべての受信者名を挿入する

---

Outlook で VBA コードを使用してメール本文にすべての受信者名を挿入する

次の手順に従って、以下の VBA コードを使用すれば、「To」フィールドのすべての受信者名をメッセージ本文に挿入できます。

1．Outlook を起動し、ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2．挿入>モジュールをクリックし、表示されたモジュールウィンドウに以下のコードを貼り付けてください。

VBA コード：受信者名をメッセージ本文に挿入する：

Sub InsertRecipientNamesToBody()
Dim xMailItem As Outlook.MailItem
Dim xRecipient As Outlook.Recipient
Dim xRecipAddress, xRecipNames, xRecipName, xFilterAddr As String
Dim xItems As Outlook.Items
Dim i As Integer
Dim xFoundContact As Outlook.ContactItem
Dim xDoc As Word.Document
On Error Resume Next
Set xMailItem = Outlook.ActiveInspector.CurrentItem
xMailItem.Recipients.ResolveAll
For Each xRecipient In xMailItem.Recipients
    xRecipAddress = xRecipient.Address
    Set xItems = Application.Session.GetDefaultFolder(olFolderContacts).Items
    For i = 1 To 3
        xFilterAddr = "[Email" & i & "Address] = " & xRecipAddress
        Set xFoundContact = xItems.Find(xFilterAddr)
        If Not (xFoundContact Is Nothing) Then
           xRecipNames = xRecipNames & xFoundContact.FullName & Chr(10)
           Exit For
        End If
    Next
    If (xFoundContact Is Nothing) Then
       xRecipName = Split(xRecipAddress, "@")(0)
       xRecipNames = xRecipNames & xRecipName & Chr(10)
    End If
Next
Set xDoc = xMailItem.GetInspector.WordEditor
xDoc.Content.InsertAfter xRecipNames
Set xMailItem = Nothing
Set xRecipient = Nothing
Set xItems = Nothing
Set xFoundContact = Nothing
End Sub

3．引き続き、Microsoft Visual Basic for Applicationsウィンドウでツール＞参照設定をクリックし、参照設定 - Project1ダイアログボックスを開きます。その後、Microsoft Word オブジェクトライブラリのオプションを利用可能な参照設定リストボックスからチェックしてください（下記スクリーンショット参照）。

4．まずOKをクリックしてダイアログを閉じてください。その後、このコードをクイックアクセスツールバーに追加する必要があります。

5．新規メールをクリックして新規メッセージを作成し、メッセージウィンドウでクイックアクセスツールバーのカスタマイズアイコンをクリックして、その他のコマンドを選択します（下記スクリーンショット参照）。

6．Outlook のオプションダイアログボックスで：

(1．)マクロを次のコマンドの選択元ドロップダウンリストから選択します。

(2．) 次に、先ほど挿入した VBA コードの名前を選択してください。

(3．)追加ボタンをクリックすると、コードがクイックアクセスツールバーのカスタマイズリストボックスに追加されます。

7．これで、マクロアイコンがクイックアクセスツールバーに表示されます（下記スクリーンショットのとおり）。

8．これで、マクロアイコンをクリックすると、「To」フィールドに入力された宛先名がメッセージ本文に自動挿入されます（下記スクリーンショットのとおり）。