Outlook で、指定した日数よりも古い未読メールを自動的に既読にする方法は？

受信トレイフォルダーに未読メールが複数ある場合、通常は「すべて既読にする」機能を使って手動で既読にできます。しかし、毎回手動で操作することなく、Outlook で特定の日数よりも古い未読メールを自動的に既読にする方法を試したことはありますか？

VBA コードで、特定の日数よりも古い未読メールを自動的に既読にする

---

VBA コードで、特定の日数よりも古い未読メールを自動的に既読にする

特定の日数よりも古い未読メールを自動的に既読にするには、以下の VBA コードが役立ちます。

1．ALT + F11キーを押すと、Microsoft Visual Basic for Applicationsウィンドウが開きます。

2．Microsoft Visual Basic for Applicationsウィンドウで、ThisOutlookSessionをProject1 (VbaProject.OTM)ペインからダブルクリックしてモジュールを開き、以下のコードを空のモジュールにコピー＆ペーストしてください。

VBA コード：特定の日数よりも古い未読メールを自動的に既読にする

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

注：上記のコードでは、次のスクリプト内の日数を変更できます。If DateDiff(「d」, xItems(i).ReceivedTime, Now) >= 15Then（ご希望の日数に変更してください）。

3．その後、このコードウィンドウを保存して閉じてください。これにより、Outlook 起動時に、事前に定義された日数よりも古いすべての未読メールが自動的に一度に既読になります。

注：このコードは、デフォルトのデータアカウントでのみご利用いただけます。