Outlook のフォルダ構造をデスクトップ（Windows エクスプローラー）にコピーするには、どうすればよいですか？

ご存じの通り、アーカイブ機能を使えばフォルダ構造を別のOutlook にコピーできますが、Outlook のフォルダ構造をデスクトップなどの特定のWindows フォルダーにコピーする方法はご存知ですか？この記事では、Outlook のフォルダ構造をWindows エクスプローラーに簡単にコピーできる VBA コードをご紹介します。

Outlook のフォルダの構造をデスクトップ（Windows エクスプローラー）にコピーする

---

Outlook のフォルダの構造をデスクトップ（Windows エクスプローラー）にコピーする

以下の手順に従って、Outlook のフォルダ構造をデスクトップまたはWindows エクスプローラーにコピーしてください。

1。ナビゲーションで、コピー元のフォルダ構造を持つフォルダーをクリックして選択し、「Alt」＋「F11」キーを押して Microsoft Visual Basic for Applications ウィンドウを開きます。

2。「ツール」＞「参照設定」をクリックして、参照設定ダイアログボックスを開きます。次に、ダイアログボックス内で「Microsoft Scripting Runtime」にチェックマークを入れ、「OK」をクリックしてください。スクリーンショットをご参照ください。

3。「挿入」＞「標準モジュール」をクリックし、以下の VBA コードを新しいモジュールウィンドウにコピー＆ペーストしてください。

VBA：Outlook のフォルダの構造をWindows エクスプローラーにコピーする

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4。この VBA を実行するには、「F5」キーを押すか「実行」ボタンをクリックしてください。

5。表示された「フォルダーの参照」ダイアログボックスで、コピーしたフォルダ構造を配置するフォルダーを選択し、「OK」ボタンをクリックしてください。スクリーンショットをご参照ください。

指定したフォルダーに移動すると、そのフォルダ構造が指定したハードディスクにコピーされていることを確認できます。スクリーンショットをご参照ください。

注：メール、予定表、タスクなどのフォルダー内のアイテムも、ハードディスク上の対応するフォルダーにコピーされます。

---

関連記事

Outlook でフォルダ構造を新しい PST データファイルにコピーするには、どうすればよいですか？