Outlook で複数の予定をタスクにすばやく変換するにはどうすればよいですか？

この記事では、Outlook で1 件または複数の予定をスピーディーかつ簡単にタスクに変換する方法をご紹介します。

ドラッグ＆ドロップで1 件の予定をタスクに変換

VBA コードを使用して複数の予定をタスクに変換

---

ドラッグ＆ドロップで1 件の予定をタスクに変換

1 件の予定をタスクに変換するには、その予定をタスクフォルダーにドラッグするだけで完了します。以下の手順に従ってください。

1。「カレンダー」ウィンドウで、タスクに変換したい予定アイテムを選択し、次のスクリーンショットのように、ナビゲーションペイン下部の「タスク」アイコンへドラッグ＆ドロップしてください。

2。すると新しい「タスク」ウィンドウが表示されるので、「保存して閉じる」ボタンをクリックして、この予定をタスクとして保存してください。

---

VBA コードを使用して複数の予定をタスクに変換

複数の予定をタスクに変換する必要がある場合は、次の VBA コードが役立ちます。以下の手順に従ってください。

1。「Alt + F11」キーを押して、「Microsoft Visual Basic for Applications」ウィンドウを開きましょう。

2。「挿入」＞「モジュール」をクリックし、開いた空のモジュールに次のコードをコピー＆ペーストしてください。

VBA コード：複数の予定をタスクに変換

Sub ConvertAppointmentsToTasks()
Dim xItemCollection As VBA.Collection
Dim xActiveWindow As Object
Dim xItem As Object
Dim xSelection As Outlook.Selection
Dim xTaskFolder As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xTaskItem As Outlook.TaskItem
On Error Resume Next
Set xItemCollection = New VBA.Collection
Set xActiveWindow = Outlook.Application.ActiveWindow
If TypeOf xActiveWindow Is Inspector Then
    Set xItem = xActiveWindow.CurrentItem
    If xItem.Class = olAppointment Then xItemCollection.Add xItem
Else
    Set xSelection = xActiveWindow.Selection
    If xSelection Is Nothing Then Exit Sub
    For Each xItem In xSelection
        If xItem.Class = olAppointment Then xItemCollection.Add xItem
    Next
End If
Set xTaskFolder = Application.Session.PickFolder
If xTaskFolder Is Nothing Then Exit Sub
For Each xAppointmentItem In xItemCollection
    Set xTaskItem = xTaskFolder.Items.Add(olTaskItem)
    With xTaskItem
        .StartDate = Format(xAppointmentItem.Start, "Short Date")
        .DueDate = Format(xAppointmentItem.End, "Short Date")
        .Subject = xAppointmentItem.Subject & " (From Appt)"
        .Categories = xAppointmentItem.Categories
        .Body = xAppointmentItem.Body
        .Save
        .Display
    End With
Next
End Sub

3。タスクに変換したい予定を複数選択し、「マクロの実行」ボタンをクリックして、このコードを実行してください。

4。すると「フォルダーの選択」ダイアログが表示されるので、「タスク」フォルダーの中から変換結果を保存したいフォルダーを選択します。

5。「OK」ボタンをクリックすると、選択したすべての予定がタスクとして作成され、その後、「タスク」ウィンドウが1 つずつ表示されて保存・閉じる操作を行います。

6。これで「タスク」フォルダーに移動すると、選択したすべての予定がタスクとしてしっかり保存されていることが確認できます。