Outlook で「名前リスト」に表示されるファックス番号を非表示にする方法は？

Outlook では、「名前の選択」リストやアドレス帳のメールアドレス列に、メールアドレスだけでなくファックス番号も表示されることがあります。それが煩わしく感じられる方のために、本記事ではファックス番号を非表示にするいくつかの方法をご紹介します。

VBA で「名前リスト」のファックス番号を非表示にする

---

VBA で「名前リスト」のファックス番号を非表示にする

「名前リスト」にすでに登録されているファックス番号を非表示にしたい場合は、以下の手順に従ってください。

1。Alt + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2。挿入＞モジュールをクリックして、新しい空のモジュールを挿入し、以下のコードをスクリプトにコピー＆ペーストしてください。

VBA：「名前の選択」に表示される既存のファックス番号を非表示にする

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3。F5キーを押してコードを実行すると、ファックス番号が非表示になります。

連絡先からファックス番号を非表示にしたい場合は、以下の手順に従ってください。

1。Alt + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを表示します。

2。ThisOutlookSessionをプロジェクト - 1ペインでダブルクリックし、以下のコードをスクリプトにコピー＆ペーストしてください。

VBA：新規連絡先を追加のファックス番号を非表示にする

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3。コードを保存して Outlook を再起動し、コードを有効化してください。

これ以降、新しく作成された連絡先のファックス番号はすべて、「名前の選択：連絡先」ウィンドウに表示されなくなります。