Excel スプレッドシートからOutlook のリマインダーをどのように作成すればよいですか？

この記事では、Excel スプレッドシートのデータをもとにOutlook のリマインダーを作成する方法をご紹介します。

VBA コードを使用してExcel スプレッドシートからOutlook のリマインダーを作成する

---

VBA コードを使用してExcel スプレッドシートからOutlook のリマインダーを作成する

Excel から Outlook のリマインダーを作成したい場合は、以下の手順に従ってください。

1．下記のスクリーンショットのように、列見出しと対応するリマインダーフィールドを含んだワークシートを作成してください。

注：「予定状況」列の数値「2」は、Outlook カレンダー上で「忙しい」と表示されることを意味します。必要に応じて、「1（仮予定）」、「3（不在勤務）」、「4（他の場所で作業中）」、または「5（空き）」に変更可能です。

2．「Alt」＋「F11」キーを押して、「Microsoft Visual Basic for Applications」ウィンドウを開きましょう。

3．「Microsoft Visual Basic for Applications」ウィンドウで、「挿入」＞「標準モジュール」をクリックし、表示されたコードウィンドウに次の VBA コードをコピーします。

VBA コード：Excel スプレッドシートからOutlook のリマインダーを作成する

Sub AddAppointments()
'Update by Extendoffice 20180608
    Dim I As Long
    Dim xRg As Range
    Dim xOutApp As Object
    Dim xOutItem As Object
    Set xOutApp = CreateObject("Outlook.Application")
    Set xRg = Range("A2:G2")
    For I = 1 To xRg.Rows.Count
        Set xOutItem = xOutApp.CreateItem(1)
        Debug.Print xRg.Cells(I, 1).Value
        xOutItem.Subject = xRg.Cells(I, 1).Value
        xOutItem.Location = xRg.Cells(I, 2).Value
        xOutItem.Start = xRg.Cells(I, 3).Value
        xOutItem.Duration = xRg.Cells(I, 4).Value
        If Trim(xRg.Cells(I, 5).Value) = "" Then
            xOutItem.BusyStatus = 2
        Else
            xOutItem.BusyStatus = xRg.Cells(I, 5).Value
        End If
        If xRg.Cells(I, 6).Value > 0 Then
            xOutItem.ReminderSet = True
            xOutItem.ReminderMinutesBeforeStart = xRg.Cells(I, 6).Value
        Else
            xOutItem.ReminderSet = False
        End If
        xOutItem.Body = xRg.Cells(I, 7).Value
        xOutItem.Save
        Set xOutItem = Nothing
    Next
    Set xOutApp = Nothing
End Sub

注：上記のコードにおける「A2:G2」は、アポイントメントを作成するためのデータ範囲です。

4．「F5」キーを押すか「実行」ボタンをクリックしてコードを実行すると、指定されたフィールドを持つすべてのアポイントメントが一括でOutlook カレンダーに追加されます。

その後、Outlook のカレンダーに移動して結果をご確認ください。スクリーンショットを参照してください：