Outlook で複数の受信者に個別にカレンダーを送信するには、どうすればよいですか？

通常、Outlook のカレンダーをメールで送信機能を使えば、受信者にカレンダーを簡単に素早く送信できます。ただし、複数の連絡先に iCalendar ファイルを添付して個別にカレンダーを送信したい場合は、1 件ずつ送信する必要があります。本記事では、Outlook で複数の受信者に個別にカレンダーを送信する簡単な方法をご紹介します。

VBA コードで複数の受信者に個別にカレンダーを送信する

---

VBA コードで複数の受信者に個別にカレンダーを送信する

複数の受信者に個別にカレンダーを送信するには、以下の VBA コードが便利です。次の手順に従ってください。

1．連絡先ペインに移動し、カレンダーを送信したい相手を選択します。

2．次に、ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

3．挿入>モジュールをクリックし、開いた空のモジュールに以下のコードをコピー＆ペーストしてください（下記スクリーンショット参照）。

VBA コード：複数の受信者に個別にカレンダーを送信する：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4．コードを挿入したら、F5キーを押してコードを実行してください。すると、フォルダーの選択ダイアログボックスが表示されるので、送信したいカレンダーを選択してください（下記スクリーンショット参照）。

5。OKをクリックすると、送信したい日付範囲を指定するプロンプトボックスが表示されます（下記スクリーンショット参照）。

6．次に、OKをクリックすると、下記のスクリーンショットのようにカレンダーが添付された新規メールが作成されます。あとは1 通ずつ送信するだけです。

---

関連記事：

Outlook で複数の受信者に個別にメールを送信するには、どうすればよいですか？

Excel からOutlook を使って、リスト宛にパーソナライズされた一斉メールを送信するにはどうすればよいですか？

Outlook で複数の下書きメールを一度に送信するには、どうすればよいですか？

Outlook で複数の受信者に他の人に知られずにメールを送信するにはどうすればよいですか？