Excel のデータから予定を作成するには、どうすればよいですか？

たとえば、以下のスクリーンショットのようにExcel ワークシートに予定データの表があり、これらのデータをOutlook カレンダーにインポートしたい場合、この作業を迅速に処理するにはどうすればよいでしょうか？

VBA コードでExcel データから予定を作成する

---

VBA コードでExcel データから予定を作成する

Excel データから予定を作成するには、次の VBA コードをご利用いただけます。以下の手順に従ってください。

1．Outlook を起動し、ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2．挿入>標準モジュールをクリックすると、標準モジュールウィンドウが表示されるので、そこに次のコードを貼り付けてください。

VBA コード：Excel データを予定にインポートする

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3．引き続き、Microsoft Visual Basic for Applicationsウィンドウでツール＞参照設定をクリックし、参照設定 - Project1ダイアログボックスを開いて、Microsoft Excel オブジェクトライブラリオプションを利用可能な参照設定リストボックス内でチェックしてください（下記スクリーンショット参照）。

4．次に、OKボタンをクリックしてからF5キーを押してこのコードを実行すると、ファイルの選択ウィンドウが表示されます。Outlook にインポートしたいExcel ファイルを選択してください（下記スクリーンショット参照）。

5。その後、OKをクリックすると、次のようなプロンプトボックスが表示されます。

6．次にOKをクリックすると、Excel データが以下のスクリーンショットのようにカレンダーにインポートされます。