Outlook から Excel にフォルダ構造をエクスポートする方法は？

本記事では、Outlook からアカウントのフォルダ構造を Excel ファイルにエクスポートする方法をご紹介します。ぜひ、本記事の手順に従ってご自身で実行してみてください。

VBA コードを使用して Outlook からアカウントのフォルダの構造を Excel にエクスポートする

---

VBA コードを使用して Outlook からアカウントのフォルダの構造を Excel にエクスポートする

以下の VBA コードが役立つかもしれません。下記の手順に従って操作してください。

1。Excel を起動し、ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2。「挿入 > モジュール」をクリックし、表示されたモジュールウィンドウに以下のコードを貼り付けてください。

VBA コード：Outlook からアカウントのフォルダの構造を Excel にエクスポートする

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3。Microsoft Visual Basic for Applicationsウィンドウで引き続き、「ツール>参照設定」をクリックして参照設定 - Project1ダイアログボックスを開き、利用可能な参照設定リストボックス内でMicrosoft Excel オブジェクトライブラリオプションにチェックを入れます（下記スクリーンショット参照）。

4。 次に「OK」ボタンをクリックし、F5キーを押してこのコードを実行します。「フォルダーの選択」ダイアログボックスが表示されたら、エクスポートしたいフォルダ構造を持つメールアカウントを選択してください（下記スクリーンショット参照）。

5。「OK」ボタンをクリックすると、ファイルの保存ウィンドウが表示されます。エクスポートされたファイルの保存場所とファイル名を指定してください（下記スクリーンショット参照）。

6。 最後に「保存」ボタンをクリックすると、指定したExcel ワークブックにエクスポートされたフォルダ構造を確認できます（下記スクリーンショット参照）。