Outlook でカテゴリに基づいてタスクを印刷するには、どうすればよいでしょうか？

Outlook のタスクにはさまざまなカラーカテゴリーが設定されており、現在、カテゴリごとに別々のページでタスク一覧を印刷したいと考えています。この操作をOutlook でどのように行えばよいでしょうか？

カテゴリごとに異なるページでタスクを手動で1 つずつ印刷する

VBA コードを使用してカテゴリごとに異なるページでタスクを印刷する

---

カテゴリごとに異なるページでタスクを手動で1 つずつ印刷する

Outlook では、異なるカテゴリに基づいてタスクを1 つずつ手動で別々のページに印刷できます。以下の手順に従ってください。

1．Outlook を起動し、タスクペインで印刷したいタスクフォルダーを選択したら、Ctrl + Eキーを押して検索ボックスを有効にしてください。その後、検索タブのカテゴリ分けアイコンをクリックし、印刷したいカラーのカテゴリを1 つ選択してください（下記スクリーンショット参照）。

2．すると、指定したカラーのカテゴリが付いたすべてのタスクが一覧表示されます（下記スクリーンショット参照）。

3．次に、ファイル＞印刷をクリックして、このタスク一覧を印刷してください（下記スクリーンショット参照）。

4．上記の手順を繰り返し、他のカラーカテゴリーを持つタスク一覧を1 つずつ手動で印刷してください。

---

VBA コードを使用してカテゴリごとに異なるページでタスクを印刷する

ここでは、カテゴリごとにタスクを分けて、それぞれ別のページで一度に印刷できる VBA コードをご紹介します。以下の手順に従って操作してください。

1．タスクペインに移動して、印刷したいタスクフォルダーを選択します。

2．次に、ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

3．次に、挿入＞モジュールをクリックし、開いた空のモジュールに以下のコードをコピー＆ペーストしてください。

VBA コード：カテゴリごとに異なるページでタスクを印刷する

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4．次に、ツール＞参照設定をクリックします。Microsoft Visual Basic for Applicationsウィンドウ内に表示される参照設定 - Project1ダイアログボックスで、使用可能な参照設定リストボックスからMicrosoft Excel オブジェクトライブラリおよびMicrosoft Scripting Runtimeの各オプションにチェックを入れてください（下記スクリーンショット参照）。

5．次に、OKボタンをクリックしてからF5キーを押し、このコードを実行します。コードの実行が完了すると、異なるカテゴリのタスク一覧がそれぞれ別のページで印刷されます。