Outlook の送信済みアイテムフォルダーから通常どおり返信するには、どうすればよいですか？

通常、「送信済みアイテム」フォルダーで「返信」機能をクリックしてすでに送信した相手に追加メッセージを送ろうとすると、自分のメールアドレスが「To」欄に表示されます（下記スクリーンショット参照）。毎回アドレスを手動で変更するのは面倒かもしれません。Outlook で、自分のアドレスではなく元の受信者のアドレスが自動的に使用されるように設定するにはどうすればよいでしょうか？

Outlook の送信済みアイテムフォルダーで「全員に返信」機能を使って通常通り返信する

Outlook の送信済みアイテムフォルダーで VBA コードを使って通常通り返信する

---

Outlook の送信済みアイテムフォルダーで「全員に返信」機能を使って通常通り返信する

Outlook では、全員に返信機能でこの問題を簡単に解決できます。以下の手順に従ってください。

送信済みメールに再度返信して元の受信者のアドレスを維持したい場合は、全員に返信ボタンをクリックしてください。すると、元の受信者のアドレスがTo 欄に表示されます（下記スクリーンショット参照）。

---

Outlook の送信済みアイテムフォルダーで VBA コードを使って通常通り返信する

送信済みメッセージに返信するとき、全員に返信機能をうっかり忘れてしまうことがあります。次の VBA コードを使えば、送信済みアイテムフォルダーから「返信」機能で通常どおり返信できるようになります。以下の手順に従ってください。

1．ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2．Microsoft Visual Basic for Applicationsウィンドウで、ThisOutlookSessionをProject1 (VbaProject.OTM)ペインからダブルクリックしてモジュールを開き、以下のコードを空のモジュールにコピー＆ペーストしてください。

VBA コード：Outlook の送信済みアイテムフォルダーで通常通り返信する：

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3．返信をクリックして送信済みアイテムフォルダー内のメールを再送信すると、元の受信者のアドレスが「To」欄に自動的に入力されます。コードを保存してOutlook を再起動し、コードを有効にしてください。