Outlook でメールに返信または転送する際に、カテゴリを保持する方法は？

通常、カテゴリが付けられたメールに返信または転送すると、送信済みメールのカテゴリは自動的に削除されます。返信や転送時にも送信メールにカテゴリを保持したい場合は、この記事でその設定方法をご紹介します。

VBA コードを使用してメールの返信または転送時にカテゴリを保持する

---

VBA コードを使用してメールの返信または転送時にカテゴリを保持する

1。ALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2。Microsoft Visual Basic for Applicationsウィンドウで、ThisOutlookSessionをProject1 (VbaProject.OTM)ペインからダブルクリックしてモジュールを開き、以下のコードを空のモジュールにコピー＆ペーストしてください。

VBA コード：メールの返信または転送時にカテゴリを保持する：

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3。その後、このコードウィンドウを保存して閉じ、Outlook を再起動してください。これにより、カテゴリ付きメールに返信または転送する際、送信メッセージ内でもカテゴリが保持されます（)送信済みアイテム参照）。スクリーンショットをご覧ください：