Excel からOutlook カレンダーに誕生日をインポートするには、どうすればよいですか？

ワークシートに大量の誕生日情報があり、それをOutlook カレンダーの予定として素早くインポートするには、どのような方法がありますか？

---

VBA コードでExcel からOutlook カレンダーに誕生日をインポートする

通常、誕生日をOutlook カレンダーに直接インポートする方法はありません。この問題を解決するため、以下の手順に従って VBA コードを作成してください。

1．Outlook にインポートしたい誕生日を含むワークシートを開き、次にALT + F11キーを押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

2．挿入>標準モジュールをクリックし、表示されたモジュールウィンドウに次のコードを貼り付けてください。

VBA コード：誕生日をOutlook カレンダーにインポートする

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3．引き続き、Microsoft Visual Basic for Applicationsウィンドウで、ツール > 参照設定をクリックします。参照設定 – VBAProjectダイアログボックスが表示されたら、Microsoft Outlook 16.0 オブジェクトライブラリオプションを、利用可能な参照設定リストボックスからチェックしてください（下記スクリーンショット参照）。

4．次に、OKをクリックしてこのダイアログボックスを閉じます。F5キーを押してこのコードを実行すると、プロンプトボックスが表示され、「名前」と「誕生日」の列を指定してください（下記スクリーンショット参照）。

5．その後、OKボタンをクリックすると、誕生日がすぐにOutlook カレンダーにインポートされます。Outlook を起動して、その結果をご確認ください（下記スクリーンショット参照）。