Outlookで特定のドメインに基づいてメールアドレスをエクスポートするにはどうすればよいですか？

Author: Xiaoyang Last Modified: 2025-08-06

Outlook内のすべての連絡先から特定のドメインを持つメールアドレスをエクスポートしたい場合は、以下のチュートリアルをお読みください。このチュートリアルでは、特定のドメインのすべてのメールアドレスをテキストファイルに抽出するためにVBAコードを適用する方法を説明します（下のスクリーンショットを参照）。

doc-export-addresses-with-domain-1

VBAコードを使用してOutlookで特定のドメインに基づいてメールアドレスをエクスポートする

すべての連絡先から特定のドメインを持つすべてのメールアドレスを抽出するには、次の手順に従ってください：

1. 新しいテキストファイルを作成し、名前を付けます（スクリーンショットを参照）：

doc-export-addresses-with-domain-2

2. 「ALT + F11」キーを押して、「Microsoft Visual Basic for Applications」ウィンドウを開きます。

3. 次に、「挿入」>「モジュール」をクリックし、以下のコードをモジュールウィンドウに貼り付けます。

「VBAコード：特定のドメインに基づいてメールアドレスをエクスポート」

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

注意: 上記のコードで、ファイルパス "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" を自分のものに変更してください。

doc-export-addresses-with-domain-4