Outlook：主催者として会議をキャンセルしても、カレンダーに予定を残す方法はありますか？

Outlook では、会議の主催者が会議をキャンセルすると、その会議は自動的にカレンダーから削除されます。ただし、場合によっては、キャンセルした会議をカレンダー上に残しておき、何らかのメモを追加したいこともあるでしょう。ところが、こうした操作を実現する機能は、残念ながらOutlook には標準で搭載されていません。本チュートリアルでは、会議をキャンセルしつつも予定としてカレンダーに保持するための2 つの VBA コードをご紹介します。

キャンセルした会議を予定としてコピーする VBA コード

---

キャンセルした会議を予定としてコピーする VBA コード

以下に、会議をキャンセルすると同時にその予定をコピー＆ペーストする2 つのコードを示します。

コードを有効化する前に、以下の2 つのオプションにチェックが入っていることをご確認ください。

Outlook を起動し、ファイル > オプションをクリックします。Outlook オプションウィンドウで、トラストセンタータブをクリックし、さらにトラストセンターの設定をクリックします。トラストセンターのウィンドウで、マクロの設定タブを選択し、すべてのマクロを有効にする（推奨されません。危険なコードが実行される可能性があります）とインストール済みのアドインにもマクロのセキュリティ設定を適用するの各オプションをチェックします。その後、OK > OKをクリックしてこのウィンドウを閉じます。Outlook を再起動します。

1。Outlook のカレンダービューに素早く切り替えて、キャンセルしたい会議を選択します。次に、Alt+F11キーを押して、Microsoft Visual Basic for Applications ウィンドウを表示します。

2。挿入>標準モジュールをクリックして、新しい空白モジュールを挿入します。その後、以下のコードをコピーして貼り付けてください。

コード：会議を予定としてコピーしてキャンセルする

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3。実行ボタンをクリックするか、F5キーを押してください。これにより、選択された会議がキャンセルされ、「Cancled & subjet」という件名の予定が作成されます。

会議を別のカレンダーに予定としてコピー＆ペーストした後にキャンセルしたい場合は、以下のコードを使用してください。

コード：会議を別のカレンダーに予定としてコピーしてキャンセルする

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

実行ボタンをクリックするか、F5キーを押すと、「フォルダーの選択」ダイアログが表示されます。ここで、予定を貼り付けるカレンダーフォルダーを選択し、OK をクリックしてください。

これで、会議はキャンセルされると同時に、選択したカレンダーフォルダーに予定としてコピー＆ペーストされました。