Word 文書の各ページを個別の PDF ファイルとして保存するには、どうすればよいですか？

著者Siluvia変更日2025-04-11

Microsoft Word には、組み込みの「名前を付けて保存」機能があり、「オプション」ダイアログでページ番号を指定すれば、各ページを個別の PDF として手動で保存できます。しかし、数百ページにも及ぶ大規模な文書では、この作業を手動で行うのは非常に時間がかかります。本記事では、すべてのページを個別の PDF ファイルとして素早く保存する方法をご紹介します。

VBA コードで各ページを個別の PDF ファイルとして一括保存

次の VBA コードを使えば、Word 文書内の各ページを自動で個別の PDF ファイルとして保存できます。手順は以下のとおりです：

処理したいWord 文書を開きます。Alt + F11を押して、「Microsoft Visual Basic for Applications」ウィンドウを起動します。

Visual Basic ウィンドウで、「挿入」>「標準モジュール」をクリックし、次の VBA コードをモジュールウィンドウに貼り付けます：

Sub SaveAsSeparatePDFs()
'Updated by Extendoffice 20180906
    Dim I As Long
    Dim xStr As String
    Dim xPathStr As Variant
    Dim xDictoryStr As String
    Dim xFileDlg As FileDialog
    Dim xStartPage, xEndPage As Long
    Dim xStartPageStr, xEndPageStr As String
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    If xFileDlg.Show <> -1 Then
        MsgBox "Please chose a valid directory", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xPathStr = xFileDlg.SelectedItems(1)
    xStartPageStr = InputBox("Begin saving PDFs starting with page __? " & vbNewLine & "(ex: 1)", "Kutools for Word")
    xEndPageStr = InputBox("Save PDFs until page __?" & vbNewLine & "(ex: 7)", "Kutools for Word")
    If Not (IsNumeric(xStartPageStr) And IsNumeric(xEndPageStr)) Then
        MsgBox "The enterng start page and end page should be number format", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xStartPage = CInt(xStartPageStr)
    xEndPage = CInt(xEndPageStr)
    If xStartPage > xEndPage Then
        MsgBox "The start page number can't be larger than end page", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    If xEndPage > ActiveDocument.BuiltInDocumentProperties(wdPropertyPages) Then
        xEndPage = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
    End If
    For I = xStartPage To xEndPage
        ActiveDocument.ExportAsFixedFormat xPathStr & "\Page_" & I & ".pdf", _
        wdExportFormatPDF, False, wdExportOptimizeForPrint, wdExportFromTo, I, I, wdExportDocumentWithMarkup, _
        False, False, wdExportCreateHeadingBookmarks, True, False, False
    Next
End Sub

「挿入」>「モジュール」が選択された状態の VBA ウィンドウと、モジュールウィンドウにコピーされた VBA コード

F5を押してコードを実行します。
表示される「参照」ウィンドウで、フォルダーを選択して PDF ファイルを保存し、「OK」をクリックします。
最初の「Kutools for Word」ダイアログボックスで開始ページ番号を入力し、「OK」をクリックしてください。
2 番目の「Kutools for Word」ダイアログボックスで、終了ページ番号を入力して「OK」をクリックします。
注：たとえば、連続する数ページ（ページ4、5、および6）を保存するには、最初のダイアログボックスに「4」を、2 つ目のダイアログボックスに「6」をそれぞれ入力してください。