Word 文書を複数のドキュメントに分割するには、どうすればよいですか？

著者Amanda Li変更日2025-01-09

大規模なWord 文書を分割する必要がある場合、このチュートリアルでは3 つの効果的な方法をご紹介します。特定の区切り文字やページ単位で VBA を使って分割する方法、あるいはKutools for Word の便利な機能を活用する方法など、あなたのニーズにぴったりの解決策が見つかります。

VBA を使用してWord 文書を指定した区切り文字で分割する
Kutools for Word を使用してWord 文書を見出し／ページ／セクション区切り／改ページで分割する
VBA を使用してWord 文書をページ単位で分割する

VBA を使用してWord 文書を指定した区切り文字で分割する

特定の区切り文字に基づいてWord 文書を自動的に分割するには、手動で分割する代わりに以下の手順で VBA を使用できます。

Microsoft Visual Basic for Applications ウィンドウを開くには、Alt + F11を押してください。

挿入>モジュールをクリックし、下記の VBA コードをモジュールウィンドウに貼り付けます。

Sub SplitNotes(delim As String, strFilename As String)
Dim doc As Document
Dim arrNotes
Dim I As Long
Dim X As Long
Dim Response As Integer
arrNotes = Split(ActiveDocument.Range, delim)
Response = MsgBox("This will split the document into " & UBound(arrNotes) + 1 & " sections. Do you wish to proceed?", 4)
If Response = 7 Then Exit Sub
For I = LBound(arrNotes) To UBound(arrNotes)
If Trim(arrNotes(I)) <> "" Then
X = X + 1
Set doc = Documents.Add
doc.Range = arrNotes(I)
doc.SaveAs ThisDocument.Path & "\" & strFilename & Format(X, "000")
doc.Close True
End If
Next I
End Sub
Sub test()
'delimiter & filename
SplitNotes "///", "Notes "
End Sub

実行ボタンをクリックするか、F5キーを押して、VBA を実行します。
Microsoft Word のポップアップで、はいをクリックして確認してください。

注：

スクリプトは、ドキュメント内のテキストを個別のファイルに分割する位置を特定するために、「///」（コードの22 行目）を検索します。ドキュメントで「///」以外の区切り文字を使用している場合は、VBA コードを修正して正しい区切り文字を反映させるか、分割位置に「///」を追加してください。
コードの22 行目にある「Notes」を任意のテキストに置き換えることで、分割後のドキュメントに意味のあるファイル名の接頭辞を付与できます。
分割されたドキュメントは、元のファイルと同じ場所に保存されます。
ドキュメントの末尾に区切り文字を追加しないでください。追加すると、空のファイルが作成されてしまいます。

Kutools for Word を使用してWord 文書を見出し／ページ／セクション区切り／改ページで分割する

Kutools for Word なら、手動操作や VBA に比べて、文書の分割がより便利で柔軟になります。見出し、ページ、セクション区切り、改ページ、n ページごと、またはカスタムページ範囲に基づく分割オプションを備え、あなたの特定のニーズに合わせて分割プロセスを自由にカスタマイズできます。

KUTOOLS PLUSで分割をクリックして、分割機能を有効にします。

文書の分割ダイアログで、以下のオプションを設定してください。

分割基準ドロップダウンリストから、分割方法をお選びください。選択可能なオプションには、「見出し 1」、「改ページ」、「セクション区切り」、「ページ」、「n ページごと」、または「カスタムページ範囲」が含まれます。
分割後のドキュメントを保存するフォルダーを選択するには、参照ボタンをクリックしてください。
文書の接頭辞フィールドに、新しいドキュメント名の接頭辞としてキーワードを入力します。ヒント：更新ボタンをクリックすると、分割されたドキュメント名をプレビューボックスで確認できます。
OK をクリックしてください。

文書は指定された方法に従って分割され、生成されたファイルは指定されたフォルダーに保存されます。

注：

n ページごとで分割する場合は、関連するボックスに数値を入力してください。
カスタムページ範囲を指定する場合は、カンマで区切って入力してください（例：1,3-5,12）。

Word で同じ作業をもっとスピーディーにこなしたいですか？ぜひKutools for Word をお試しください。日々の業務がぐっとラクに。

ダウンロード詳細はこちら

Word 文書をChrome やEdge のようにタブで開いて、複数のファイルを快適に閲覧＆編集！

Chrome、Safari、Edge で複数のウェブページを閲覧するのと同じ感覚で、Office Tab を今すぐ無料でお試しください！を使えば、複数の Word 文書を1 つのウィンドウで開いて簡単に管理できます。各文書のタブをクリックするだけで、瞬時に切り替え可能！
Office Tab を今すぐ無料でお試しください！

Chrome のように、1 つのウィンドウで複数の Word 文書を閲覧

VBA を使用してWord 文書をページ単位で分割する

Word 文書をすばやく複数のドキュメント（各ドキュメント1 ページ）に分割する必要がある場合は、VBA マクロを使用してこのタスクを自動化できます。以下の手順に従ってください。

Alt + F11 を押して、Microsoft Visual Basic for Applicationsウィンドウを開きます。

挿入>モジュールをクリックし、次の VBA コードを新しいモジュールウィンドウに貼り付けます：

Sub SplitIntoPages()
Dim docMultiple As Document
Dim docSingle As Document
Dim rngPage As Range
Dim iCurrentPage As Integer
Dim iPageCount As Integer
Dim strNewFileName As String
Application.ScreenUpdating = False 'Makes the code run faster and reduces screen flicker a bit.
Set docMultiple = ActiveDocument 'Work on the active document
Set rngPage = docMultiple.Range 'Instantiate the range object
iCurrentPage = 1
'Get the document's page count
iPageCount = docMultiple.Content.ComputeStatistics(wdStatisticPages)
Do Until iCurrentPage > iPageCount
    If iCurrentPage = iPageCount Then
        rngPage.End = ActiveDocument.Range.End 'Last page (no next page)
    Else
        'Find the beginning of the next page
        'Must use the Selection object. The Range.Goto method will not work on a page
        Selection.GoTo wdGoToPage, wdGoToAbsolute, iCurrentPage + 1
        'Set the end of the range to the point between the pages
        rngPage.End = Selection.Start
    End If
    rngPage.Copy 'Copy the page into the Windows clipboard
    Set docSingle = Documents.Add 'Create a new document
    docSingle.Range.Paste 'Paste the clipboard contents to the new document
    'Remove any manual page break to prevent a second blank
    docSingle.Range.Find.Execute Findtext:="^m", ReplaceWith:=""
    'Build a new sequentially numbered file name based on the original multi-paged file name and path
    strNewFileName = Replace(docMultiple.FullName, ".doc", "_" & Right$("000" & iCurrentPage, 4) & ".doc")
    docSingle.SaveAs strNewFileName 'Save the new single-paged document
    iCurrentPage = iCurrentPage + 1 'Move to the next page
    docSingle.Close 'Close the new document
    rngPage.Collapse wdCollapseEnd 'Go to the next page
Loop 'Go to the top of the do loop
Application.ScreenUpdating = True 'Restore the screen updating
'Destroy the objects.
Set docMultiple = Nothing
Set docSingle = Nothing
Set rngPage = Nothing
End Sub