文字列から最初または最後の単語を削除する

このチュートリアルでは、Excelで数式を使用してセル内のテキスト文字列から最初または最後の単語のみを削除する方法について説明します。

セル内の文字列から最初の単語を削除する
セル内の文字列から最後の単語を削除する

セル内の文字列から最初の単語を削除する

このセクションでは、RIGHT、LEN、およびFIND関数を組み合わせて使用して、セル内の文字列から最初の単語を削除する方法を学びます。

汎用的な数式

=RIGHT(A1,LEN(A1)-FIND(" ",A1))

引数

この数式の使い方は？

1. 結果を出力するための空白セルを選択します。

2. 次の数式を入力し、Enterキーを押します。その後、その結果セルのフィルハンドルを下にドラッグして、他のセルにも数式を適用します。

=RIGHT(B3,LEN(B3)-FIND(" ",B3))

注意: この数式では、B3は最初の単語を削除したいテキスト文字列が含まれているセルです。必要に応じて変更してください。

この数式の仕組みは？

=RIGHT(B3,LEN(B3)-FIND(" ",B3))

1. LEN(B3): LEN関数は、テキスト文字列 "Mr ana varela (Home)" の全長を計算し、結果として20を返します。

2. FIND(" ",B3): 単語はスペースで区切られているため、ここでFIND関数はテキスト文字列 "Mr ana varela (Home)" 内の最初のスペースの位置を見つけ、結果として3を返します。

3. RIGHT(B3,20-3): RIGHT関数は、テキスト文字列 "Mr ana varela (Home)" の右側から17文字（20-3=17）を抽出します。結果は "ana varela (Home)" です。

セル内の文字列から最後の単語を削除する

セル内のテキスト文字列から最後の単語を削除したい場合は、次のように操作できます。

汎用的な数式

=LEFT(TRIM(A1),FIND("~",SUBSTITUTE(A1," ","~",LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(A1)," ",""))))-1)

引数

この数式の使い方は？

1. 結果を配置するための空白セルを選択します。ここでは、セルD3を選択します。

2. 次の数式を入力し、Enterキーを押します。結果セルを選択し、そのフィルハンドルを下にドラッグして、他のセルにも数式を適用します。

=LEFT(TRIM(B3),FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))-1)

注意: この数式では、B3は最後の単語を削除したいテキスト文字列が含まれているセルです。必要に応じて変更してください。

この数式の仕組みは？

=LEFT(TRIM(B3),FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))-1)

1. TRIM(B3): TRIM関数は、文字列 "Mr ana varela (Home)" からすべての余分なスペースを削除し、単語間には1つのスペースだけを残します。ここでの結果は "Mr ana varela (Home)" です。

2. FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))

• LEN(TRIM(B3)): TRIM関数が "Mr ana varela (Home)" を返すので、LEN関数は文字列 "Mr ana varela (Home)" 内の文字数を返し、結果として20を返します。
• LEN(SUBSTITUTE(TRIM(B3)," ","")): SUBSTITUTE関数は、テキスト文字列 "Mr ana varela (Home)" 内のすべてのスペースを削除し、結果として "Mranavarela(Home)" を返します。そしてLEN関数は "Mranavarela(Home)" の全長を計算し、結果として17を得ます。
• SUBSTITUTE(B3," ","~",20-17): ここでSUBSTITUTE関数は、テキスト文字列 "Mr ana varela (Home)" 内の3番目のスペース（20-17=3）を文字 "~" に置き換えます。結果は "Mr ana varela~(Home)" です。
• FIND("~","Mr ana varela~(Home)"): FIND関数は、テキスト文字列 "Mr ana varela (Home)" 内の文字 "~" の位置を返します。結果は14です。

3. LEFT("Mr ana varela (Home)",14-1): LEFT関数は、テキスト文字列 "Mr ana varela (Home)" の左側から13文字を抽出します。最終的な結果は Mr ana varela です。

関連する関数

関連する数式