Excel でセル内のテキスト文字列を特定の文字で分割する

このチュートリアルでは、Excel でテキスト文字列を特定の文字に基づいて分割し、別々の列に出力する方法をご紹介します。

Excel でセル内のテキスト文字列を特定の文字で分割するには？

下図のように、列 B に「-」で区切られたテキスト文字列のリストがあり、それを3 つの別々の列に分割して出力したい場合、以下の数式が役立ちます。

汎用数式

左側のテキストを分割するための汎用数式

=LEFT(text_string,FIND(「Char」, text_string)-1)

中央のテキストを分割するための汎用数式

=MID(text_string, FIND(「Char」, text_string) + 1, FIND(「Char」, text_string,FIND(「Char」, text_string)+1) - FIND(「Char」, text_string) - 1)

右側のテキストを分割するための汎用数式

=RIGHT(text_string,LEN(text_string) - FIND(「Char」, text_string, FIND(「Char」, text_string) + 1))

上記の数式の引数

これらの数式の使い方

まず、特定の文字に基づいて最初のテキスト文字列を分割します

1。結果を出力する空白セル（ここでは C3）を選択します。

2。以下の数式を入力し、Enterキーを押します。その後、LEFT 関数を含むセルを下方向にドラッグして、他のセルにも適用します。

=LEFT(B3,FIND("-",B3)-1)

次に、特定の文字に基づいて中央のテキスト文字列を分割します

1。結果を表示する空白セル（例：D3）を選択してください。

2。以下の数式を入力してEnterキーを押し、結果セルを選択します。その後、フィルハンドルを下にドラッグして、他のセルにも数式を適用しましょう。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

最後に、特定の文字に基づいて末尾のテキスト文字列を分割します

1。結果を表示する空白セル（例：E3）を選択してください。

2。以下の数式を入力し、Enterキーを押します。結果セルを選択し、フィルハンドルを下にドラッグして他のセルにも数式を適用します。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

これで、列 B の各セル内のテキスト文字列が3 つの部分に分割されました。

ヒント：テキスト文字列を特定の文字で2 つの部分にのみ分割したい場合は、上記の LEFT 関数で最初の部分を取得した後、下図のように以下の RIGHT 関数を使って2 番目の部分を抽出できます。

=RIGHT(B3,LEN(B3)-FIND("-",B3))

これらの数式の動作原理

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)FIND 関数は、テキスト文字列「KTE-Jan-359」内で最初に出現する「-」の位置を返します。その結果は4 です。
• LEFT(B3,4-1)：LEFT 関数は、テキスト文字列「KTE-Jan-359」の左端から3 文字（4－1＝3）を抽出します。結果は「KTE」です。
  注：テキスト文字列の4 番目の位置に最初の「-」が含まれているため、これを除外するために1 を引く必要があります。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1：FIND 関数は、テキスト文字列「KTE-Jan-359」内で最初に現れる「-」の位置を返します。この例では、結果は4 です。
  注：最初の「-」がテキストの4 文字目に位置するため、その後ろから文字列を抽出するには、4 に1 を加えて開始位置を調整する必要があります。つまり、4＋1＝5 となります。
• FIND("-",B3,FIND("-",B3)+1)ここでは、FIND("-", "KTE-Jan-359", 4+1) として表示されています。FIND 関数は、「KTE-Jan-359」の5 文字目以降で「-」の位置を検索し、結果として8 を返します。
• MID(B3, 5, 8 - 4 - 1)MID(KTE-Jan-359,5,3) は、MID 関数を使ってテキスト文字列「KTE-Jan-359」の5 文字目から3 文字を抽出することを意味し、その結果は「Jan」です。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)LEN 関数は、テキスト文字列「KTE-Jan-359」の全長を計算し、結果として11 を返します。
• FIND("-",B3,FIND("-",B3)+1)FIND 関数は、「KTE-Jan-359」の5 文字目以降で「-」の位置を検索し、結果として8 を返します。
• RIGHT(B3,11 - 8))RIGHT 関数は、「KTE-Jan-359」の右側から3 文字（11－8）を抽出し、その結果は「359」になります。

関連関数

関連数式