Outlookからすべてのカテゴリをクリアするにはどうすればよいですか？

Author: Xiaoyang Last Modified: 2025-05-23

例えば、Outlookで多くのアイテムに色分けされたカテゴリが適用されているとします。これらのすべてのカテゴリをアイテムから削除する必要がある場合、Outlookでこの作業を迅速かつ簡単に処理するにはどうすればよいでしょうか？

「すべてのカテゴリをクリア」機能を使用して特定のフォルダからすべてのカテゴリをクリアする

VBAコードを使用して特定のアカウントからすべてのカテゴリをクリアする

「すべてのカテゴリをクリア」機能を使用して特定のフォルダからすべてのカテゴリをクリアする

特定のフォルダ内のカテゴリだけをクリアする必要がある場合は、次の手順を行ってください：

1. 色分けされたカテゴリを削除したいフォルダをクリックし、Ctrl + Aキーを押してすべてのアイテムを選択します。

2. その後、右クリックして、コンテキストメニューから「カテゴリを追加します > すべてクリア」を選択してください。スクリーンショットをご覧ください：

3. これで、その特定のフォルダ内のすべての色分けされたカテゴリが一度にクリアされます。

VBAコードを使用して特定のアカウントからすべてのカテゴリをクリアする

メール、タスク、連絡先、ノートなど、あるアカウント内のすべてのアイテムからカテゴリをクリアするには、以下のVBAコードが役立ちます：

1. クリーンアップしたいアカウントのメールをクリックし、ALT + F11キーを押してMicrosoft Visual Basic for Applicationsウィンドウを開きます。

2. 「挿入 > モジュール」をクリックし、以下のマクロをモジュールウィンドウに貼り付けます。

VBAコード: 特定のアカウントからすべてのカテゴリをクリアする：

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. 次に、 F5キーを押して実行すると、選択したアカウントからすべてのカテゴリがクリアされたことを知らせるプロンプトボックスが表示されます。スクリーンショットをご覧ください：